股票指标> 推荐指标 > 通达信炸板、涨停后倍量阴分时均线战法套装 炸板分时均线战法套装升级解密版(2024/1/22 13:57:00)

通达信炸板、涨停后倍量阴分时均线战法套装 炸板分时均线战法套装升级解密版

{炸倍均主图源码如下}

DRAWTEXT_FIX(1,0.00,0.00,0,'板块：'),COLORCYAN;
DRAWTEXT_FIX(1,0.05,0.00,0,STRCAT(STRCAT(STRCAT(STRCAT(HYBLOCK,'__'),GNBLOCK),'__'),DYBLOCK)),COLORCYAN; {板块信息}

{虚拟成交量}
TOTAL:=IF(PERIOD=1,5,IF(PERIOD=2,15,IF(PERIOD=3,30,IF(PERIOD=4,60,IF(PERIOD=5,TOTALFZNUM,1)))));
MTIME:=MOD(FROMOPEN,TOTAL);
CTIME:=IF(MTIME<0.5,TOTAL,MTIME);
VVOL:=IF((CURRBARSCOUNT=1 AND DYNAINFO(8)>1),VOL*(TOTAL+3)/(CTIME+3),VOL);
今夕比:VVOL/REF(VOL,1),COLORWHITE,NODRAW;

ISST股:=NAMEINCLUDE('ST');
ZTBL:=IF(FINANCE(3)=2,0.3,IF((FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6),0.2,0.1));
涨停价:=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL));
跌停价:=DTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL));
非一字涨停:=CLOSE>=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH!=LOW AND HIGH>0;
一字涨停:=CLOSE>=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH=LOW AND HIGH>0;
涨停:=非一字涨停 OR 一字涨停;
非一字跌停:=CLOSE<=DTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH!=LOW AND LOW>0;
一字跌停:=CLOSE<=DTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH=LOW AND LOW>0;
跌停:=非一字跌停 OR 一字跌停;
日涨幅:=(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100;

弱分界:EMA(COST(85),10),COLORRED,DOTLINE;
强分界:EMA(COST(99),10),COLORGREEN,DOTLINE;
DRAWBAND(弱分界,RGB(20,20,20),强分界,RGB(60,60,8));
BSTJ:=弱分界>=REF(弱分界,1) AND 强分界>=REF(强分界,1);
QHTJ:=IF(BSTJ,强分界,弱分界);
DRAWBAND(QHTJ,RGB(139,35,35),弱分界,RGB(00,00,00));

DRAWKLINE(H,O,L,C);

{涨跌停标识}
STICKLINE(非一字涨停,OPEN,CLOSE,3,0),COLORMAGENTA;
STICKLINE(非一字涨停,HIGH,LOW,0,0),COLORMAGENTA;
STICKLINE(非一字跌停,OPEN,CLOSE,3,0),COLORFF8000;
STICKLINE(非一字跌停,HIGH,LOW,0,0),COLORFF8000;
STICKLINE(一字涨停,OPEN,CLOSE,3,0),COLORMAGENTA;
STICKLINE(一字跌停,OPEN,CLOSE,3,0),COLORBLUE;

{炸与翘标识}
炸:=HIGH>=涨停价 AND CLOSE<HIGH;
翘:=LOW<=跌停价 AND CLOSE=涨停价;
STICKLINE(炸,HIGH,MIN(OPEN,CLOSE),0,0),COLOR5900B3;
STICKLINE(炸,OPEN,CLOSE,0.18,0),COLOR5900B3;
STICKLINE(翘,MIN(OPEN,CLOSE),LOW,0,0),COLORFF8000;
STICKLINE(翘,OPEN,CLOSE,0.18,0),COLORFF8000;

{昨日炸板高与炸板时均线}
DRAWTEXT(炸,HIGH,'炸'),COLORMAGENTA;
ZBT:=BARSLAST(炸);
ZBT2:=REF(ZBT,ZBT+1)+ZBT+1;
ZBT3:=REF(ZBT,ZBT2+2)+ZBT2+2;
STICKLINE(CURRBARSCOUNT<=CONST(ZBT3)+1 AND ZBT>=0,REF(H,ZBT),REF(H,ZBT),4.2,-1),COLORMAGENTA;{炸板分时高}
STICKLINE(CURRBARSCOUNT<=CONST(ZBT2)+1 AND ZBT>=0,REF(H,ZBT),REF(H,ZBT),4.2,-1),COLORMAGENTA;{炸板分时高}
STICKLINE(CURRBARSCOUNT<=CONST(ZBT)+1 AND ZBT>=0,REF(H,ZBT),REF(H,ZBT),4.2,0),COLORMAGENTA;{炸板分时高}
DRAWTEXT(ISLASTBAR,REF(H,ZBT),VARCAT(VAR2STR(REF(H,ZBT),2),'←炸分高')),COLORMAGENTA;
STICKLINE(CURRBARSCOUNT<=CONST(ZBT3)+1 AND ZBT>=0,REF(AMOUNT/V/100,ZBT),REF(AMOUNT/V/100,ZBT),4.2,-1),COLORLIGRAY;{炸板分时均}
STICKLINE(CURRBARSCOUNT<=CONST(ZBT2)+1 AND ZBT>=0,REF(AMOUNT/V/100,ZBT),REF(AMOUNT/V/100,ZBT),4.2,-1),COLORLIGRAY;{炸板分时均}
STICKLINE(CURRBARSCOUNT<=CONST(ZBT)+1 AND ZBT>=0,REF(AMOUNT/V/100,ZBT),REF(AMOUNT/V/100,ZBT),4.2,0),COLORLIGRAY;{炸板分时均}
DRAWTEXT(ISLASTBAR,REF(AMOUNT/V/100,ZBT),VARCAT(VAR2STR(REF(AMOUNT/V/100,ZBT),2),'↙炸分均')),COLORLIGRAY,DRAWABOVE;

八日内不破均突:BETWEEN(ZBT,1,8) AND REF(IF(ZBT=0 AND BETWEEN(CLOSE,AMOUNT/V/100,REF(H,ZBT)),1,IF(ZBT>0,COUNT(CLOSE<REF(AMOUNT/V/100,ZBT),ZBT)=0 AND COUNT(CLOSE>REF(REF(H,ZBT),1),ZBT)=0,0)),1)=1 AND CLOSE>REF(REF(H,ZBT),1),COLORMAGENTA,NODRAW;
DRAWICON(八日内不破均突,LOW,34);
BRNTTJ:=BETWEEN(ZBT,1,8) AND (CROSS(CLOSE,REF(AMOUNT/V/100,ZBT)) OR (REF(CLOSE<=REF(AMOUNT/V/100,ZBT),1) AND CLOSE>REF(AMOUNT/V/100,ZBT))) AND REF(COUNT(CLOSE>REF(REF(H,ZBT),1),ZBT),1)=0 AND CLOSE>OPEN;
八日内突:BRNTTJ AND REF(COUNT(BRNTTJ,ZBT),1)=0,COLORYELLOW,NODRAW;
DRAWICON(八日内突,LOW,1);
CBTTJ:=ZBT>8 AND REF(CLOSE,1)<=REF(REF(AMOUNT/V/100,ZBT),1) AND CLOSE>REF(REF(AMOUNT/V/100,ZBT),1) AND CLOSE>OPEN;
超八突:CBTTJ AND REF(COUNT(CBTTJ,ZBT),1)<=2,COLORRED,NODRAW;
DRAWICON(超八突,LOW,38);
CBJTJ:=ZBT>8 AND REF(CLOSE,1)<=REF(REF(H,ZBT),1) AND CLOSE>REF(REF(H,ZBT),1) AND CLOSE>OPEN;
超八加:CBJTJ AND REF(COUNT(CBJTJ,ZBT),1)<=2,COLORWHITE,NODRAW;
DRAWICON(超八加,LOW,23);

{涨停后倍量阴}
THBLY:=REF(涨停,1) AND CLOSE<OPEN AND (VOL>=REF(VOL,1)*1.9 OR AMOUNT>=REF(AMOUNT,1)*1.9);{涨停后倍量阴}
DRAWTEXT(THBLY,HIGH*1.012,'倍阴'),COLORLIGREEN;
THBLYT:=BARSLAST(THBLY);
STICKLINE(THBLY,OPEN,CLOSE,3,0),COLORLIGREEN;
STICKLINE(THBLY,LOW,HIGH,0,0),COLORLIGREEN;
THBLYT2:=REF(THBLYT,THBLYT+1)+THBLYT+1;
THBLYT3:=REF(THBLYT,THBLYT2+2)+THBLYT2+2;
STICKLINE(CURRBARSCOUNT<=CONST(THBLYT3)+1 AND THBLYT>=0,REF(AMOUNT/V/100,THBLYT),REF(AMOUNT/V/100,THBLYT),4.2,-1),COLORLICYAN;{停后倍量阴分时均}
STICKLINE(CURRBARSCOUNT<=CONST(THBLYT2)+1 AND THBLYT>=0,REF(AMOUNT/V/100,THBLYT),REF(AMOUNT/V/100,THBLYT),4.2,-1),COLORLICYAN;{停后倍量阴分时均}
STICKLINE(CURRBARSCOUNT<=CONST(THBLYT)+1 AND THBLYT>=0,REF(AMOUNT/V/100,THBLYT),REF(AMOUNT/V/100,THBLYT),4.2,0),COLORLICYAN;{停后倍量阴分时均}
DRAWTEXT(ISLASTBAR,REF(AMOUNT/V/100,THBLYT),VARCAT(VAR2STR(REF(AMOUNT/V/100,THBLYT),2),'←倍阴均')),COLORLICYAN;
STICKLINE(CURRBARSCOUNT<=CONST(THBLYT3)+1 AND THBLYT>=0,REF(HIGH,THBLYT),REF(HIGH,THBLYT),4.2,-1),COLORLIGREEN;{停后倍量阴高}
STICKLINE(CURRBARSCOUNT<=CONST(THBLYT2)+1 AND THBLYT>=0,REF(HIGH,THBLYT),REF(HIGH,THBLYT),4.2,-1),COLORLIGREEN;{停后倍量阴高}
STICKLINE(CURRBARSCOUNT<=CONST(THBLYT)+1 AND THBLYT>=0,REF(HIGH,THBLYT),REF(HIGH,THBLYT),4.2,0),COLORLIGREEN;{停后倍量阴高}
DRAWTEXT(ISLASTBAR,REF(HIGH,THBLYT),VARCAT(VAR2STR(REF(HIGH,THBLYT),2),'←倍阴H')),COLORLIGREEN;

KXTJ:=IF(HIGH=CLOSE OR (OPEN>=REF(HIGH,1) AND CLOSE>OPEN),1,IF(LOW=OPEN,HIGH-MAX(OPEN,CLOSE)<MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE),IF(HIGH-MAX(OPEN,CLOSE)>MIN(OPEN,CLOSE)-LOW,MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE)>(HIGH-MAX(OPEN,CLOSE))*1.38,IF(LOW<OPEN AND HIGH>CLOSE,MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE)>MIN(OPEN,CLOSE)-LOW AND MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE)>HIGH-MAX(OPEN,CLOSE),DRAWNULL))));
破倍阴均:REF(CLOSE,1)<=REF(REF(AMOUNT/V/100,THBLYT),1) AND CLOSE>REF(REF(AMOUNT/V/100,THBLYT),1) AND KXTJ,COLORYELLOW,NODRAW;
DRAWICON(破倍阴均 AND EMA(CLOSE,5)>=REF(EMA(CLOSE,5),1) AND CLOSE>EMA(CLOSE,5) AND REF(COUNT(破倍阴均,THBLYT),1)<=2,LOW*0.98,11);
破倍阴高:REF(CLOSE,1)<=REF(REF(HIGH,THBLYT),1) AND CLOSE>REF(REF(HIGH,THBLYT),1) AND KXTJ,COLORMAGENTA,NODRAW;
DRAWICON(破倍阴高 AND EMA(CLOSE,5)>=REF(EMA(CLOSE,5),1) AND CLOSE>EMA(CLOSE,5) AND REF(COUNT(破倍阴高,THBLYT),1)<=2,OPEN,25);

{红底绿顶9}
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD:=(DIF-DEA)*2;

A111:=C>REF(C,4);
NT:=BARSLASTCOUNT(A111);
TJ11:=NT=9;
DRAWTEXT(NT=9 AND CLOSE>=OPEN,(OPEN+CLOSE)/2,'9'),COLORGREEN;
DRAWTEXT(NT=9 AND CLOSE<OPEN,(OPEN+CLOSE)/2,'9'),COLORFF0000;
D9T:=BARSLAST(TJ11);
D9T2:=REF(D9T,D9T+1)+D9T+1;
STICKLINE(CURRBARSCOUNT<=CONST(D9T2)+1 AND D9T>=0,REF(H,D9T),REF(H,D9T),4,0),COLORCDCDB4;{白水平线--绿九划线}
DRAWTEXT(ISLASTBAR,REF(H,D9T),VARCAT(VAR2STR(REF(H,D9T),2),'←绿9限')),COLORCDCDB4;

B111:=C<REF(C,4);
NT0:=BARSLASTCOUNT(B111);
TJ21:=NT0=9;
DRAWTEXT(NT0=9,(OPEN+CLOSE)/2,'9'),COLORRED;

{九转}
ZF9%:=C/REF(C,1)>1.09;
首次:=DYNAINFO(4)>0 AND BARSLASTCOUNT(ZF9%)=1;
AS1:=BARSLAST(TJ11>0);
AS2:=REF(H,AS1);
AS3:=AS1>4 AND C/REF(C,1)>1.09 AND C>AS2 AND 首次;
AS4:=FILTER(AS3,13);
DRAWTEXT(FILTER(AS3>0,3),LOW*0.998,'9'),COLORGREEN;

{黄金支撑线}
VAR0A:=EMA(EMA(EMA(CLOSE,2),2),2);
短线:=(MA(VAR0A,13)*0.99);
短线副:=(MA(VAR0A,13)*0.999);
TLAMSENR:=MAX(MAX((HIGH-LOW),ABS((REF(CLOSE,1)-HIGH))),ABS((REF(CLOSE,1)-LOW)));
VAR0B:=MA(TLAMSENR,13);
VAR1A:=(REF(CLOSE,1)-REF(VAR0B,1));
黄金支撑:(HHV(VAR1A,12)),COLORYELLOW;
DRAWTEXT(ISLASTBAR,黄金支撑,VARCAT(VAR2STR(黄金支撑,2),'←金支撑')),COLORYELLOW;

{大阴21位，反弹必须过这条线3天才能买入}
DF5:=(C-REF(C,1))/REF(C,1)*100<-5.5 OR C/O<=0.955;
DYT:=BARSLAST(DF5);
DYT2:=REF(DYT,DYT+1)+DYT+1;
XZ:=(REF(O,DYT)+REF(C,DYT))/2;
STICKLINE(CURRBARSCOUNT<=CONST(DYT2)+1 AND (C<REF(XZ,DYT) OR BARSLASTCOUNT(C>REF(XZ,DYT))<=3),XZ,XZ,2,0),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT<=CONST(DYT2)+1 AND DYT=1,XZ,VARCAT(VAR2STR(XZ,2),'←上线3日买')),COLORGREEN,DRAWABOVE;

三阴:=REF(DOWNNDAY(CLOSE,3),1);
收阳:=C>REF(C,1) AND C>=O;
止跌:=三阴 AND 收阳;
STICKLINE(止跌,MIN(OPEN,CLOSE),MIN(OPEN,CLOSE)+(MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE))/4,2.5,0),COLORBROWN;
DRAWTEXT(止跌,LOW,'↑止'),COLORRED;
ZDT:=BARSLAST(止跌);
ZDT2:=REF(ZDT,ZDT+1)+ZDT+1;
STICKLINE(CURRBARSCOUNT<=CONST(ZDT)+1 AND ZDT>=0,REF(OPEN,ZDT),REF(OPEN,ZDT),4,0),COLOR0000BB;{红水平线--止跌划线}
DRAWTEXT(ISLASTBAR,REF(OPEN,ZDT),VARCAT(VAR2STR(REF(OPEN,ZDT),2),'←止损')),COLOR0000BB;
反转线:REF(H,BARSLAST(CONST(BARSLAST(止跌))+4=CURRBARSCOUNT)),COLOR65EBD0,DOTLINE;
DRAWTEXT(ISLASTBAR,反转线,VARCAT(VAR2STR(反转线,2),'←反转')),COLOR65EBD0;{调整后站上这个线才有可能反转}

{量王}
{虚拟总量}
X_10:=IF(PERIOD=1,5,IF(PERIOD=2,15,IF(PERIOD=3,30,IF(PERIOD=4,60,IF(PERIOD=5,TOTALFZNUM,1)))));
X_20:=MOD(FROMOPEN,X_10);
X_30:=IF(X_20<0.5,X_10,X_20);
VVZL:=IF(CURRBARSCOUNT=1 AND DYNAINFO(8)>1,AMOUNT*(X_10+3)/(X_30+3),AMOUNT);

总量:=AMOUNT;
量比:=VVOL/REF(MA(VOL,5),1);
BLA:=VVZL>=REF(总量,1)*1.9 AND (IF(C<=O,C>REF(C,1),1));
BLB:=VVOL>=REF(VOL,1)*2 AND (IF(C<=O,C>REF(C,1),1));
倍量:=BLA AND BLB;
{量王}
天量:=总量=HHV(总量,120);
量王:=天量 AND BLA AND 量比>2 AND (BARSCOUNT(C)+1)>120;

{量王画线}
LWT:=BARSLAST(量王);
LWT2:=REF(LWT,LWT+1)+LWT+1;
LWT3:=REF(LWT,LWT2+2)+LWT2+2;
STICKLINE(量王,MIN(OPEN,CLOSE),(OPEN+CLOSE)/2,2.5,0),COLORLIGREEN;
DRAWTEXT(CURRBARSCOUNT=CONST(LWT)+1,MIN(OPEN,CLOSE)+(MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE))/4,'←王3'),COLORMAGENTA;
DRAWTEXT(CURRBARSCOUNT=CONST(LWT2)+1,MIN(OPEN,CLOSE)+(MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE))/4,'←王2'),COLORYELLOW;
DRAWTEXT(CURRBARSCOUNT=CONST(LWT3)+1,MIN(OPEN,CLOSE)+(MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE))/4,'←王1'),COLORGREEN;

{资金流动情况}
AAV:=VOL/((H-L)*2-ABS(C-O));
KKPU1:=IF(C>OPEN,AAV*(HIGH-LOW),IF(C<OPEN,AAV*((HIGH-OPEN)+(C-LOW)),VOL/2));
KKPU2:=IF(C>OPEN,0-AAV*((HIGH-C)+(OPEN-LOW)),IF(C<OPEN,0-AAV*(HIGH-LOW),0-VOL/2));
净流入:=(KKPU1+KKPU2)/99;
KKPU3:=(C/REF(C,1)-1)*100;
DRAWTEXT_FIX(ISLASTBAR AND 净流入>=200 AND KKPU3>=3,0.92,0.0,0,VARCAT(VARCAT('净买：',VAR2STR(净流入,0)),'万')),COLORRED;
DRAWTEXT_FIX(ISLASTBAR AND 净流入<-200 AND KKPU3<=-2,0.92,0.0,0,VARCAT(VARCAT('流出：',VAR2STR(净流入,0)),'万')),COLORGREEN;
AP:=AMOUNT/10000;
占比:=净流入/AP*100;
DRAWTEXT_FIX(ISLASTBAR AND 占比<15,0.92,0.05,0,STRCAT('净流占比：',STRCAT(CON2STR(占比,0),'%'))),COLORYELLOW;
DRAWTEXT_FIX(ISLASTBAR AND 占比>=15,0.92,0.05,0,STRCAT('净流占比：',STRCAT(CON2STR(占比,0),'%'))),COLORMAGENTA;

{屏幕下部提示}
涨家:=STRCAT(STRCAT('总上涨：',CON2STR(DYNAINFO(60),0)),' 只');
跌家:=STRCAT(STRCAT('总下跌：',CON2STR(DYNAINFO(61),0)),' 只');
DRAWTEXT_FIX(ISLASTBAR,0,1,0,涨家),COLORRED;
DRAWTEXT_FIX(ISLASTBAR,0.12,1,0,跌家),COLORGREEN;
涨跌比:=STRCAT(STRCAT('涨跌比：',CON2STR(DYNAINFO(60)/(DYNAINFO(60)+DYNAINFO(61))*100,2)),' %');
DRAWTEXT_FIX(ISLASTBAR,0.23,1,0,涨跌比),COLORWHITE;

{屏幕下部提示}
DRAWTEXT_FIX(ISLASTBAR AND (CLOSE/LLV(CLOSE,10)-1)*100>=15,0.88,1,0,STRCAT('十日最大涨幅:',STRCAT(CON2STR((CLOSE/LLV(CLOSE,10)-1)*100,2),' %'))),COLORRED;
DRAWTEXT_FIX(ISLASTBAR AND (CLOSE/LLV(CLOSE,10)-1)*100<15,0.88,1,0,STRCAT('十日最大涨幅:',STRCAT(CON2STR((CLOSE/LLV(CLOSE,10)-1)*100,2),' %'))),COLORWHITE;





{炸倍均副图源码如下:}

ISST股:=NAMEINCLUDE('ST');
ZTBL:=IF(FINANCE(3)=2,0.3,IF((FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6),0.2,0.1));
涨停价:=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL));
跌停价:=DTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL));
非一字涨停:=CLOSE>=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH!=LOW AND HIGH>0;
一字涨停:=CLOSE>=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH=LOW AND HIGH>0;
涨停:=非一字涨停 OR 一字涨停;
非一字跌停:=CLOSE<=DTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH!=LOW AND LOW>0;
一字跌停:=CLOSE<=DTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH=LOW AND LOW>0;
跌停:=非一字跌停 OR 一字跌停;
日涨幅:=(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100;

{炸板分时均价线}
炸:=HIGH>=涨停价 AND CLOSE<HIGH;
ZBT:=BARSLAST(炸);
炸分均:=REF(AMOUNT/V/100,ZBT);
炸板强势:BETWEEN(ZBT,0,8) AND IF(ZBT=0 AND BETWEEN(CLOSE,AMOUNT/V/100,REF(H,ZBT)),1,IF(ZBT>0,COUNT(CLOSE<REF(AMOUNT/V/100,ZBT),ZBT)=0 AND COUNT(CLOSE>REF(REF(H,ZBT),1),ZBT)=0,0)),COLORLIRED,NODRAW;
STICKLINE(炸板强势,0,0.38,0.05,0),COLORLIRED;
八日内不破均突:BETWEEN(ZBT,1,8) AND REF(IF(ZBT=0 AND BETWEEN(CLOSE,AMOUNT/V/100,REF(H,ZBT)),1,IF(ZBT>0,COUNT(CLOSE<REF(AMOUNT/V/100,ZBT),ZBT)=0 AND COUNT(CLOSE>REF(REF(H,ZBT),1),ZBT)=0,0)),1)=1 AND CLOSE>REF(REF(H,ZBT),1),COLORMAGENTA;
BRNTTJ:=BETWEEN(ZBT,1,8) AND (CROSS(CLOSE,REF(AMOUNT/V/100,ZBT)) OR (REF(CLOSE<=REF(AMOUNT/V/100,ZBT),1) AND CLOSE>REF(AMOUNT/V/100,ZBT))) AND REF(COUNT(CLOSE>REF(REF(H,ZBT),1),ZBT),1)=0 AND CLOSE>OPEN;
八日内突:BRNTTJ AND REF(COUNT(BRNTTJ,ZBT),1)=0,COLORYELLOW,STICK,LINETHICK2;
CBTTJ:=ZBT>8 AND REF(CLOSE,1)<=REF(REF(AMOUNT/V/100,ZBT),1) AND CLOSE>REF(REF(AMOUNT/V/100,ZBT),1) AND CLOSE>OPEN;
超八突:CBTTJ AND REF(COUNT(CBTTJ,ZBT),1)<=2,COLORRED;
CBJTJ:=ZBT>8 AND REF(CLOSE,1)<=REF(REF(H,ZBT),1) AND CLOSE>REF(REF(H,ZBT),1) AND CLOSE>OPEN;
超八加:CBJTJ AND REF(COUNT(CBJTJ,ZBT),1)<=2,COLORWHITE,STICK,LINETHICK2;

{涨停后倍量阴}
THBLY:=REF(涨停,1) AND CLOSE<OPEN AND (VOL>=REF(VOL,1)*1.9 OR AMOUNT>=REF(AMOUNT,1)*1.9);{涨停后倍量阴}
THBLYT:=BARSLAST(THBLY);
倍阴强势:BETWEEN(THBLYT,0,8) AND IF(THBLYT=0 AND BETWEEN(CLOSE,REF(LOW,THBLYT),AMOUNT/V/100),1,IF(THBLYT>0,COUNT(CLOSE<REF(LOW,THBLYT),THBLYT)=0 AND COUNT(CLOSE>REF(REF(AMOUNT/V/100,THBLYT),1),THBLYT)=0,0)),COLORLICYAN,NODRAW;
STICKLINE(倍阴强势,0,0.38,0.05,0),COLORLICYAN;
KXTJ:=IF(HIGH=CLOSE OR (OPEN>=REF(HIGH,1) AND CLOSE>OPEN),1,IF(LOW=OPEN,HIGH-MAX(OPEN,CLOSE)<MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE),IF(HIGH-MAX(OPEN,CLOSE)>MIN(OPEN,CLOSE)-LOW,MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE)>(HIGH-MAX(OPEN,CLOSE))*1.38,IF(LOW<OPEN AND HIGH>CLOSE,MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE)>MIN(OPEN,CLOSE)-LOW AND MAX(OPEN,CLOSE)-MIN(OPEN,CLOSE)>HIGH-MAX(OPEN,CLOSE),DRAWNULL))));
PBYJ:=REF(CLOSE,1)<=REF(REF(AMOUNT/V/100,THBLYT),1) AND CLOSE>REF(REF(AMOUNT/V/100,THBLYT),1) AND KXTJ;
破倍阴均:PBYJ AND EMA(CLOSE,5)>=REF(EMA(CLOSE,5),1) AND CLOSE>EMA(CLOSE,5) AND REF(COUNT(PBYJ,THBLYT),1)<=2,COLORLIGREEN;
PBYH:=REF(CLOSE,1)<=REF(REF(HIGH,THBLYT),1) AND CLOSE>REF(REF(HIGH,THBLYT),1) AND KXTJ;
破倍阴高:PBYH AND EMA(CLOSE,5)>=REF(EMA(CLOSE,5),1) AND CLOSE>EMA(CLOSE,5) AND REF(COUNT(PBYH,THBLYT),1)<=2,COLORMAGENTA,LINETHICK2;





{炸倍均分时主图引用}

ISST股:=NAMEINCLUDE('ST');
ZTBL:=IF(FINANCE(3)=2,0.3,IF((FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6),0.2,0.1));
涨停价:=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL));
非一字涨停:=CLOSE>=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH!=LOW AND HIGH>0;
一字涨停:=CLOSE>=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL)) AND HIGH=LOW AND HIGH>0;
涨停:=非一字涨停 OR 一字涨停;

{资金流动情况}
AAV:=VOL/((H-L)*2-ABS(C-O));
KKPU1:=IF(C>OPEN,AAV*(HIGH-LOW),IF(C<OPEN,AAV*((HIGH-OPEN)+(C-LOW)),VOL/2));
KKPU2:=IF(C>OPEN,0-AAV*((HIGH-C)+(OPEN-LOW)),IF(C<OPEN,0-AAV*(HIGH-LOW),0-VOL/2));
净流入:(KKPU1+KKPU2)/99;
KKPU3:=(C/REF(C,1)-1)*100;
AP:=AMOUNT/10000;
占比:净流入/AP*100;

昨开:REF(OPEN,1);
昨收:REF(CLOSE,1);
前开:REF(OPEN,2);
前收:REF(CLOSE,2);
均价:=AMOUNT/V/100;
ZJJ:REF(均价,1);
ZTG:REF(CLOSE,BARSLAST(涨停));

{炸缩分时主图引用}
C_1:=HIGH>=涨停价-0.01 AND CLOSE<HIGH;
ZBT:=BARSLAST(C_1);
ZFH:=REF(H,BARSLAST(C_1));
ZZFH:REF(ZFH,1);{昨日炸板分时高}
ZFJ:=REF(AMOUNT/V/100,ZBT);
ZZFJ:REF(ZFJ,1);{昨日炸板分时均线}

THBLYT:=BARSLAST(REF(涨停,1) AND CLOSE<OPEN AND VOL>=REF(VOL,1)*1.9);{涨停后倍量阴}
THBLYJ:=REF(AMOUNT/V/100,THBLYT);
ZTHBLYJ:REF(THBLYJ,1);{昨日涨停后倍量阴分时均线};

{黄金支撑线}
VAR0A:=EMA(EMA(EMA(CLOSE,2),2),2);
短线:=(MA(VAR0A,13)*0.99);
短线副:=(MA(VAR0A,13)*0.999);
TLAMSENR:=MAX(MAX((HIGH-LOW),ABS((REF(CLOSE,1)-HIGH))),ABS((REF(CLOSE,1)-LOW)));
VAR0B:=MA(TLAMSENR,13);
VAR1A:=(REF(CLOSE,1)-REF(VAR0B,1));
JZC:(HHV(VAR1A,12));






{炸倍分时主图 源码如下：}


DRAWTEXT_FIX(1,0.00,0.00,0,'板块：'),COLORCYAN;
DRAWTEXT_FIX(1,0.05,0.00,0,STRCAT(STRCAT(STRCAT(STRCAT(HYBLOCK,'__'),GNBLOCK),'__'),DYBLOCK)),COLORCYAN; {板块信息}

ISST股:=NAMEINCLUDE('ST');
ZTBL:=IF(FINANCE(3)=2,0.3,IF(FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6,0.2,0.1));
涨停价:=ZTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL));
跌停价:=DTPRICE(REF(CLOSE,1),IF(ISST股,0.05,ZTBL));

{931涨速}
AT:=REF(C,BARSLAST(DAY!=REF(DAY,1)));
AT1:=DYNAINFO(4);
AT2:=AT-AT1;
D:=DYNAINFO(20);
SPEED:=AT2/AT1*100;
速度931:=STRCAT('【速进】',CON2STR(SPEED,2));
DRAWTEXT_FIX(ISLASTBAR AND SPEED<2 AND SPEED>0.432,0.38,0.85,0,速度931),COLOR00FFFF;
DRAWTEXT_FIX(ISLASTBAR AND SPEED>=2.0,0.38,0.85,0,速度931),COLOR0000FF;

{分时强势}
FSQ_01:=BARSLAST(DATE!=REF(DATE,1));
FSQ_02:=DYNAINFO(3);
FSQ_03:=(CLOSE/FSQ_02-1)*100;
FSQ_04:=CROSS(FSQ_03,5) OR CROSS(FSQ_03,7) OR CROSS(FSQ_03,9);
FSQ:=HHVBARS(CLOSE,FSQ_01)=0 AND FSQ_04;
DRAWICON(FSQ,CLOSE,38);

正偏差:=IF(NAMELIKE('ST') OR NAMELIKE('*'),4.8,IF(FINANCE(3)=2,28.8,IF(FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6,19.2,9.6)));
负偏差:=IF(NAMELIKE('ST') OR NAMELIKE('*'),-4.8,IF(FINANCE(3)=2,-28.8,IF(FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6,-19.2,-9.6)));

ZZFH:IF(BETWEEN((ZBJYY.ZZFH#DAY-DYNAINFO(3))/DYNAINFO(3)*100,负偏差,正偏差) AND IF(CODELIKE('11') OR CODELIKE('12'),0,1),ZBJYY.ZZFH#DAY,DRAWNULL),COLORMAGENTA;{昨日炸板分时高线}
DRAWTEXT(BARSTATUS=1,ZZFH*1.005,STRCAT(STRCAT('炸分高：',VAR2STR(ZZFH,2)),'元')),COLORMAGENTA;
DRAWTEXT(LONGCROSS(CLOSE,ZZFH,3),CLOSE*0.998,'↑突'),COLORMAGENTA;
ZZFJ:IF(BETWEEN((ZBJYY.ZZFJ#DAY-DYNAINFO(3))/DYNAINFO(3)*100,负偏差,正偏差) AND IF(CODELIKE('11') OR CODELIKE('12'),0,1),ZBJYY.ZZFJ#DAY,DRAWNULL),COLORRED;{昨日炸板分时均线}
DRAWTEXT(BARSTATUS=1,ZZFJ,STRCAT(STRCAT('炸分均：',VAR2STR(ZZFJ,2)),'元')),COLORRED;
DRAWTEXT(LONGCROSS(CLOSE,ZZFJ,3),CLOSE*0.998,'↑突'),COLORRED;
ZTHBLYJ:IF(BETWEEN((ZBJYY.ZTHBLYJ#DAY-DYNAINFO(3))/DYNAINFO(3)*100,负偏差,正偏差) AND IF(CODELIKE('11') OR CODELIKE('12'),0,1),ZBJYY.ZTHBLYJ#DAY,DRAWNULL),COLORGREEN;{昨日涨停倍量阴分时均线}
DRAWTEXT(BARSTATUS=1,ZTHBLYJ*1.005,STRCAT(STRCAT('倍阴均：',VAR2STR(ZTHBLYJ,2)),'元')),COLORGREEN;
DRAWTEXT(LONGCROSS(CLOSE,ZTHBLYJ,3),CLOSE*0.998,'↑突'),COLORGREEN;

ZJJ:IF(ZBJYY.ZJJ#DAY!=DRAWNULL AND BETWEEN((ZBJYY.ZJJ#DAY-DYNAINFO(3))/DYNAINFO(3)*100,负偏差,正偏差) AND IF(FINANCE(3)=6,0,1),ZBJYY.ZJJ#DAY,DRAWNULL),COLORFFA800;{昨日均价线}
DRAWTEXT(ISLASTBAR,ZJJ*1.005,STRCAT(STRCAT('昨均价：',VAR2STR(ZJJ,2)),'元')),COLORFFA800;
DRAWTEXT(LONGCROSS(ZJJ,CLOSE,3),ZJJ*1.01,'↓止损'),COLORFFA800;

JZC:IF(ZBJYY.JZC#DAY!=DRAWNULL AND BETWEEN((ZBJYY.JZC#DAY-DYNAINFO(3))/DYNAINFO(3)*100,负偏差,正偏差) AND IF(FINANCE(3)=6,0,1),ZBJYY.JZC#DAY,DRAWNULL),COLORC4FFFF;{黄金支撑线}
DRAWTEXT(ISLASTBAR,JZC,STRCAT(STRCAT('金支撑：',VAR2STR(JZC,2)),'元')),COLORC4FFFF;
DRAWTEXT(LONGCROSS(JZC,CLOSE,3),JZC*1.01,'↓止盈'),COLORCYAN;
DRAWTEXT(LONGCROSS(CLOSE,JZC,3),JZC,'↑买'),COLORC4FFFF;

{432/-432,864/-864}
XSA:=IF(ISST股,1.0432,IF(FINANCE(3)=2,1.2592,IF((FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6),1.1728,1.0864)));
XSB:=IF(ISST股,1.0216,IF(FINANCE(3)=2,1.1296,IF((FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6),1.0864,1.0432)));
XSC:=IF(ISST股,0.9784,IF(FINANCE(3)=2,0.8704,IF((FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6),0.9136,0.9568)));
XSD:=IF(ISST股,0.9568,IF(FINANCE(3)=2,0.7048,IF((FINANCE(3)=3 OR FINANCE(3)=4 OR FINANCE(3)=6),0.8272,0.9136)));
NOTEXT01:ZBJYY.昨收#DAY*XSA,COLORMAGENTA,DOTLINE;
DRAWTEXT(BARSTATUS=1,ZBJYY.昨收#DAY*XSA*1.005,STRCAT(STRCAT('864：',VAR2STR(ZBJYY.昨收#DAY*XSA,2)),'元')),COLORMAGENTA;
NOTEXT02:ZBJYY.昨收#DAY*XSB,COLORRED,DOTLINE;
DRAWTEXT(BARSTATUS=1,ZBJYY.昨收#DAY*XSB*1.005,STRCAT(STRCAT('432：',VAR2STR(ZBJYY.昨收#DAY*XSB,2)),'元')),COLORRED;
NOTEXT03:ZBJYY.昨收#DAY*XSC,COLORYELLOW,DOTLINE;
DRAWTEXT(BARSTATUS=1,ZBJYY.昨收#DAY*XSC*1.005,STRCAT(STRCAT('-432：',VAR2STR(ZBJYY.昨收#DAY*XSC,2)),'元')),COLORYELLOW;
NOTEXT04:ZBJYY.昨收#DAY*XSD,COLORGREEN,DOTLINE;
DRAWTEXT(BARSTATUS=1,ZBJYY.昨收#DAY*XSD*1.005,STRCAT(STRCAT('-864：',VAR2STR(ZBJYY.昨收#DAY*XSD,2)),'元')),COLORGREEN;

现价:=CLOSE;
均价:=SUM(CLOSE*VOL,240)/SUM(VOL,240);
量价齐升:=HHV(V,0)>REF(EMA(HHV(V,0),5),1) AND CLOSE>REF(EMA(CLOSE,7),1);
EMA7:EMA(CLOSE,7),COLORRED,DOTLINE;
NOTEXT05:IF(EMA7<REF(EMA7,1) AND CLOSE<=EMA7,EMA7,DRAWNULL),COLORFFA800;
NOTEXT06:IF(HHV(V,0)>REF(EMA(HHV(V,0),5),1) AND CLOSE>REF(EMA(CLOSE,7),1) AND BETWEEN(TIME,0930,1030),EMA7,DRAWNULL),COLORMAGENTA,LINETHICK2;
NOTEXT07:IF(HHV(V,0)>REF(EMA(HHV(V,0),5),1) AND CLOSE>REF(EMA(CLOSE,7),1) AND BETWEEN(TIME,1030,1130),EMA7,DRAWNULL),COLORRED,LINETHICK2;
EMA2:=EMA(CLOSE,26);
SWS:=DMA(EMA(CLOSE,26),MAX(1,100*(SUM(VOL,5)/(3*CAPITAL))));
EMA26:IF(CODELIKE('11') OR CODELIKE('12'),EMA2,SWS),COLORGREEN,DOTLINE;
DRAWTEXT(ISLASTBAR,EMA26*1.005,VARCAT(VAR2STR(EMA26,2),'←支撑')),COLORGREEN;
NOTEXT08:IF(EMA26<REF(EMA26,1) AND CLOSE<=EMA26,EMA26,DRAWNULL),COLOR9B6C00;
支撑有效:BARSLASTCOUNT(EMA26>=REF(EMA26,1))>=2 AND CLOSE>EMA26 AND 均价>=REF(均价,1),COLORYELLOW,NODRAW;
突破有效:EMA26>=REF(EMA26,1) AND EMA7>=REF(EMA7,1) AND CLOSE>=MAX(EMA7,EMA26) AND 均价>=REF(均价,1) AND 量价齐升,COLORRED,NODRAW;
DRAWICON(FILTER(CROSS(支撑有效,0.5),7),EMA26,44);
DRAWICON(FILTER(CROSS(突破有效,0.5),7),EMA7,1);
管住手:(EMA7<REF(EMA7,1) AND CLOSE<=EMA7) OR (EMA26<REF(EMA26,1) AND CLOSE<=EMA26),COLORFF8000,NODRAW;

{主力来了}
XX:=SUM(AMOUNT,BARSCOUNT(CLOSE))/SUM(V*100,BARSCOUNT(CLOSE));
主力:=EXPMA(CLOSE/XX,20);
大户:=EXPMA(CLOSE/XX,60);
散户:=EXPMA(CLOSE/XX,120);
主力来了:=主力>大户 AND 大户>散户 AND C>EXPMA(C,20) AND EXPMA(C,10)>EXPMA(C,20) AND EXPMA(C,20)>EXPMA(C,60) AND 主力=HHV(主力,30) AND CROSS(主力,1.003);
DRAWICON(主力来了,C,34);
DRAWTEXT(主力来了,C,'←有主力'),COLORYELLOW;

{捉牛信号}
DIF12:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA12:=EMA(DIF12,9);
MACD12:=(DIF12-DEA12)*2;
AA0:=MACD12>00 AND DIF12>0 AND DEA12>0;
NX:=MA(((SLOPE(C,20)*5)+C),10);
A100:=HOUR=10 AND MINUTE=0;
A20:=HHV(H,30);
A30:=BARSLAST(A100);
A40:=REF(A20,A30);
A50:=CONST(A40);
A80:=CLOSE>A50 AND REF(C<=A50,1) AND CLOSE>NX;
AB:=FILTER(A80,100);
A90:=DYNAINFO(3);
AC:=CLOSE<=A90*1.04 AND CLOSE>A90;
量比:=V/REF(MA(V,5),1);
捉牛:=AA0 AND AB AND AC AND A40>A90 AND 量比>=1;
DRAWICON(捉牛,A50,38);
DRAWTEXT(捉牛,C*0.998,'←牛'),COLORMAGENTA;

{屏幕上提示}
DRAWTEXT_FIX(ISLASTBAR AND ZBJYY.净流入#DAY>=200 AND DYNAINFO(14)*100>=3,0.8,0.088,0,VARCAT(VARCAT('净买：',VAR2STR(ZBJYY.净流入#DAY,0)),'万')),COLORRED;
DRAWTEXT_FIX(ISLASTBAR AND ZBJYY.净流入#DAY<-200 AND DYNAINFO(14)*100<=-2,0.8,0.088,0,VARCAT(VARCAT('流出：',VAR2STR(ZBJYY.净流入#DAY,0)),'万')),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR AND ZBJYY.占比#DAY<15,0.9,0.088,0,STRCAT('净流占比：',STRCAT(CON2STR(ZBJYY.占比#DAY,0),'%'))),COLORYELLOW;
DRAWTEXT_FIX(ISLASTBAR AND ZBJYY.占比#DAY>=15,0.9,0.088,0,STRCAT('净流占比：',STRCAT(CON2STR(ZBJYY.占比#DAY,0),'%'))),COLORMAGENTA;

{屏幕下提示}
分时偏差:=STRCAT(STRCAT('分时偏差：',CON2STR((DYNAINFO(7)-DYNAINFO(11))/DYNAINFO(11)*100,2)),' %');
DRAWTEXT_FIX(ISLASTBAR,0.88,1,0,分时偏差),COLORWHITE;





未来函数检测结果如下：
该公式包含未来函数:COST
该公式包含未来函数:CAPITAL
该公式包含未来函数:DYNAINFO
该公式包含未来函数:FINANCE
解密、编写股票、期货策略请联系QQ或微信同号：88652583
相关股票指标公式
定制、找人做指标公式联系我们
  • QQ：88652583
  • 邮箱：88652583@qq.com
  • 工作时间：8:30-23:00
  • 微信：88652583或扫描如下二维码
    • 指标公式网微信联系方式


联系我们  |  指标公式网  |  指标网   |  指标公式  |   加入收藏   |  设为主页

@2005-2023 浙ICP备2024071487号-2 指标公式网别名指标网仅为互联网文章，所有指标公式及文章仅供学习研究,并不构成投资建议，请勿以此为依据进行股票交易，由此引起的投资亏损与本站无关。指标公式网均来源互联网收集整理，如不慎侵犯了你的权益，请联系我们告知，我们将做删除处理
QQ：88652583 微信 88652583
sitemap站点地图