指标公式说明
1. 均线系统与K线
绘制K线图。
计算并显示5日（白色）、10日（青色）、20日（品红）、30日（绿色）、60日（浅红）、90日（蓝色）移动平均线。
使用`DRAWBAND`函数填充均线之间的区域，形成色带：
60日与90日均线间填充深紫色至深灰色渐变。
20日与30日均线间填充黄色至黑色渐变。
10日与20日均线间填充红色至黑色渐变。
2. 高低点标记
近期高点：标记最近13个周期内的最高价位置（品红色点状线），若该高点出现在最近6个周期内，则用粗柱线突出显示。
近期低点：标记最近13个周期内的最低价位置（绿色点状线），若该低点出现在最近6个周期内，则用粗柱线突出显示。
突破信号：当收盘价上穿“近期高点”时，在K线下方标注“↑”箭头（青色），并记录此突破条件（不画线）。
3. 财务数据标注
在K线图固定位置（由`CURRBARSCOUNT`值决定）标注以下财务数据：
主营业务利润（万元）。
每股收益（元）。
每股净资产（元）。
标注位置经过调整，以避免与信息地雷重叠。
4. 买进信号（多种策略）
策略一（RSI类）：基于随机指标（KDJ）的变体计算，当满足特定金叉且数值条件时，在K线下方标注“↖买进”黄色文字，并将对应K线实体填充为黄色。
策略二（通道突破）：当股价上穿基于5日均线计算的特定上轨时，在K线上方标注“砸”字（白色）。
策略三（庄家散户线）：通过计算“小股民”与“庄家”两条曲线，产生交易信号：
当“小股民”线上穿“庄家”线且处于低位（<30）时，标注“←低吸”（浅红色）。
当“庄家”线上穿“小股民”线且处于高位（>70）时，标注“←高抛”。
策略四（威廉指标W&R）：
当威廉指标上穿-81超卖线时，标注“W&R”红色文字，并在前一日收盘价位置显示“卖”图标。
当威廉指标下穿-19超买线时，标注“W&R”绿色文字，并在当日最高价上方显示“买”图标。
策略五（18日均线）：当18日均线走平或向上且股价上穿该均线时，在K线下方标注“跟”字。
策略六（动态买价）：
醉白K买进：当股价上穿动态计算的“买价”均线时，用白色空心K线和点状线标记。
醉黄K加码：当股价上穿动态计算的“加码价”均线时，用黄色空心K线和点状线标记。
5. 成交量副图指标
将成交量（V）通过特定算法映射到价格坐标轴上，形成“成交量K线”：
阳量柱为红色实心。
阴量柱为青色空心。
绘制成交量5日（白色）和10日（青色）均线。
在成交量柱上标记特殊信号：
标记20日最低量位置（图标）。
涨停日（涨幅>9.9%）量柱为红色实心。
跌停日（跌幅>9.9%）量柱为绿色实心。
放倍量（≥2倍前一日）时，在量柱顶部画白色短横线。
放巨量（≥3倍前一日）时，在量柱顶部画黄色短横线。
成交量买点：当成交量创13日新低且3日均线上行时，在量柱上方标注“买”字（洋红色）。
6. 乖离率计算（未显示）
计算6日、12日、24日乖离率（BIAS），并计算其加权平均值（BIAS），但未在图表上绘制线条。这些变量可供其他公式调用或作为条件判断使用。
DRAWBAND(MA(CLOSE,60),RGB(25,0,25),MA(CLOSE,90),RGB(16,16,16));
DRAWBAND(MA(CLOSE,20),RGB(255,255,0),MA(CLOSE,30),RGB(0,0,0));
DRAWBAND(MA(CLOSE,10),RGB(255,0,0),MA(CLOSE,20),RGB(0,0,0));
MA5:MA(CLOSE,5),COLORFFFFFF;
MA10:MA(CLOSE,10),COLOR00FFFF;
MA20:MA(C,20),COLORFF00FF;
MA30:MA(C,30),COLOR00FF00;
MA60:MA(CLOSE,60),COLORFF9988;
MA90:MA(CLOSE,90),COLOR0000FF;
DRAWKLINE(HIGH,OPEN,LOW,CLOSE);
BDGD:=C=HHV(C,13);
GDSJ:=BARSLAST(FILTER(CROSS(0.8,BDGD),2))+1;
高点:REF(C,GDSJ),COLORFF00FF,POINTDOT;
突破:CROSS(C,REF(高点,1)),COLOR00FFFF,POINTDOT,NODRAW;
STICKLINE(GDSJ<=6,高点,高点,3,0),COLORFF00FF;
DRAWTEXT(突破,LOW,'↑'),COLOR00FFFF;
BDDD:=C=LLV(C,13);
DDSJ:=BARSLAST(FILTER(CROSS(0.8,BDDD),2))+1;
低点:REF(C,DDSJ),COLOR00FF00,POINTDOT;
STICKLINE(DDSJ<=6,低点,低点,3,0),COLOR00FF00;
高点1:=REFDATE(HHV(H,140),DATE);
调整:=0.99;{这里是避免跟信息地雷冲突}
DRAWNUMBER(CURRBARSCOUNT=123,高点1*调整,FINANCE(20)/10000);
DRAWTEXT(CURRBARSCOUNT=110,高点1*调整,'主营利润(万):');
DRAWNUMBER(CURRBARSCOUNT=93,高点1*调整,FINANCE(21)/10000);
DRAWTEXT(CURRBARSCOUNT=80,高点1*调整,'每股收益(元):');
DRAWNUMBER(CURRBARSCOUNT=63,高点1*调整,FINANCE(33));
DRAWTEXT(CURRBARSCOUNT=55,高点1*调整,'每股净资产(元):');
DRAWNUMBER(CURRBARSCOUNT=35,高点1*调整,FINANCE(34));
A3:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
A4:=SMA(A3,3,1);
A5:=SMA(A4,3,1);
A6:=3*A4-2*A5;
A7:=C-REF(C,1);
A8:=100*EMA(EMA(A7,6),6)/EMA(EMA(ABS(A7),6),6);
买:=LLV(A8,2)=LLV(A8,7) AND COUNT(A8<0,2) AND CROSS(A8,MA(A8,2));
DRAWTEXT(FILTER(买=1,5),LOW-0.05,'↖买进'),COLORYELLOW;
STICKLINE(买,OPEN,CLOSE,2,0),COLORYELLOW;
XS:=MA(LOW,5)*(1-5/100),LINETHICK0;
XS1:=MA(HIGH,5)*(1+5/100);
DRAWTEXT(CROSS(XS1,C),H*1.01,'砸'),COLORWHITE;
VAR2:=(2*CLOSE+HIGH+LOW)/4;
VAR3:=IF(YEAR>=2099 AND MONTH>2,0,1);
VAR4:=LLV(LOW,5); VAR5:=HHV(HIGH,4);
小股民:=EMA((VAR2-VAR4)/(VAR5-VAR4)*100,4)*VAR3;
庄家:=EMA(0.667*REF(小股民,1)+0.333*小股民,2)*VAR3;
DRAWTEXT(CROSS(小股民,庄家) AND 小股民<30,L-0.05,'←低吸'),COLORLIRED;
DRAWTEXT(CROSS(庄家,小股民) AND 小股民>70,H+0.05,'←高抛');
B1:=REF(CLOSE,1);
WR:=-100*(HHV(HIGH,28)-CLOSE)/(HHV(HIGH,28)-LLV(LOW,28));
DRAWICON(FILTER(CROSS(WR,(0 - 81)),10),B1,13);
DRAWICON(FILTER(CROSS((0 -19),WR),10),H*1.02,15);
DRAWTEXT(FILTER(CROSS(WR,(0 - 81)),21),L*0.99,' W&R'),COLORRED;
DRAWTEXT(FILTER(CROSS(0 -19,WR),21),H*1.01,' W&R'),COLORGREEN;
MA18:=MA(C,18);
跟:=IF(MA18>=REF(MA18,3) AND CROSS(CLOSE,MA18),1,0);
DRAWTEXT(MA18>=REF(MA18,3) AND CROSS(CLOSE,MA18),LOW*0.96,'跟'),COLOR7F52AF;
买价:=((C-REF(MA5,1))/5+MA5)*1.004;
买条件:=CROSS(C,买价) AND 买价>REF(买价,1);
醉白K买进:IF(买条件,L,H),COLORWHITE,POINTDOT;
STICKLINE(买条件,H,L,0,1),COLORWHITE,LINETHICK2;
STICKLINE(买条件,O,C,4,1),COLORWHITE,LINETHICK2;
加码价:=((C-REF(MA10,1))/20+MA10)*1.004;
加码条件:=CROSS(C,加码价) AND 加码价>REF(加码价,1);
醉黄K加码:IF(加码条件,L,H),COLORYELLOW,POINTDOT;
STICKLINE(加码条件,H,L,0,1),COLORYELLOW,LINETHICK2;
STICKLINE(加码条件,O,C,4,1),COLORYELLOW,LINETHICK2;
HH0:=CONST(HHV(H,120))*1;
LL0:=CONST(LLV(L,120))*1;
MM0:=CONST((HH0+LL0)/2);
HH1:=IF(CONST(C)<MM0,LL0-(HH0-LL0)*0.4,LL0-(HH0-LL0)*0.4),COLORRED;
LL1:=LL0;HLMAX:=MAX(HH1,LL1);
HLMIN:=MIN(HH1,LL1);
HLMN1:=(HLMAX+HLMIN)/2;
HLMN2:=(HLMAX-HLMIN);
HLMN3:=HHV(V,250)/2;
HLMN4:=HHV(V,250);
VZ:=(V-HLMN3)*HLMN2/HLMN4+HLMN1;
STICKLINE(C>=O,VZ,(0-HLMN3)*HLMN2/HLMN4+HLMN1,2.5,1),COLORRED;
STICKLINE(C<O,VZ,(0-HLMN3)*HLMN2/HLMN4+HLMN1,2.5,0),COLORCYAN;
(MA(V,5)-HLMN3)*HLMN2/HLMN4+HLMN1,COLORFFFFFF;
(MA(V,10)-HLMN3)*HLMN2/HLMN4+HLMN1,COLOR00FFFF;
T:=V=LLV(V,20);
DRAWICON(T,(V-HLMN3)*HLMN2/HLMN4+HLMN1,1);
STICKLINE(C/REF(C,1)>1.099,VZ,(0-HLMN3)*HLMN2/HLMN4+HLMN1,2,0),COLORRED;
STICKLINE(C/REF(C,1)<0.901,VZ,(0-HLMN3)*HLMN2/HLMN4+HLMN1,2,0),COLORGREEN;
VY:=(0-HLMN3)*HLMN2/HLMN4+HLMN1;
STICKLINE(V>=2*REF(V,1),VZ,VY,0.3,0),COLORWHITE;
STICKLINE(V>=3*REF(V,1),VZ,VY,0.3,0),COLORYELLOW;
MA13:=MA(C,3);
UU:=1,V<=LLV(V,13) AND MA13>REF(MA13,1);
TJ:=1,REF(V,1)<=LLV(V,13) AND MA13>REF(MA13,1),COLORRED,LINETHICK3;
DRAWTEXT(TJ=1,(V-HLMN3)*HLMN2/HLMN4+HLMN1+0.2,'买')COLORMAGENTA;
BIAS11:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
BIAS12:=(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100;
BIAS13:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
BIAS1:=(C-MA(C,6))/MA(C,6)*100;
BIAS2:=(C-MA(C,12))/MA(C,12)*100;
BIAS3:=(C-MA(C,24))/MA(C,24)*100;
BIAS:=(BIAS1+2*BIAS2+3*BIAS3)/6;
