本公式分为云破和指破两个公式，主图中的绿线为云破公式的压力线，红线为指破公式的压力线）：
1、云破公式原理就是前面K线峰顶出现过高开回落的大阴线后股价开始下跌，经过一段时间的整理后股价又开始上涨，突然有一天股价突破前面的峰顶大阴线的最高价，此时就会出现云破的信号（包括突破回落，信号也不会消失）。
2、指破公式原理就是前面K线峰顶出现过避雷针（也就是长上影线）后股价开始下跌，经过一段时间的整理后股价又开始上涨，突然有一天股价突破前面的峰顶长上影的最高价，此时就会出现云破的信号（包括突破回落，信号也不会消失）。
公式操作要点：
出现信号后看是否为好的买入票，可以根据以下几点择优买入。
1、对K线位置和均线的判断：
以下为几种好的形态：
当日K线位置不高，经过一段时间调整后底部刚起涨的，均线已经调整的差不多的。
当日K线位置处在前面一波上涨后的回调，短期各均线高度粘合（或均线多头排列好的）。
当日K线位置处在一波上涨的中途，均线多头排列好的，前面为慢牛上涨的，前面涨幅也不是很大的。
2、距离前面峰顶大阴（长上影）的时间周期长短
当日信号出现距离前面峰顶大阴（长上影）的时间周期越长的爆发力也相对要大点（但也不是绝对的）。
当日信号出现距离峰顶大阴（长上影）的周期很短，K线位置很高且均线乖离率很大的，很容易夭折。
出信号后，2-3天未有效上涨（云顶线或指尖线上）的可以先出局，后面做跟踪，等下一次再次突破这两条线时，再看情况二次买入(参考二次买信号)。
本公式信号比较少，翻动股票的时候你会觉得没有信号，没有显示，但这不是公式的错误，建议先用公式选股一次如下图。选股出来结果然后再翻动股票就可以看到信号
{云指破主图源码如下}
{云指破---通达信主图}
MA1:MA(CLOSE,5);
MA2:MA(CLOSE,10);
MA3:MA(CLOSE,20);
MA4:MA(CLOSE,30);
MA5:MA(CLOSE,60);
MA6:MA(CLOSE,120);
BAA:=O>REF(H,1) AND C<O AND H/O<1.01;
BAB:=VOL=HHV(VOL,30);
XG:=BAA AND BAB;
云顶线:IF(XG,H,REF(H,BARSLAST(XG))),LINETHICK2,COLORGREEN;
DAA:=BARSLAST(XG);
DAB:=BETWEEN(DAA,3,380);
EAA:=(L<REF(H,DAA) AND H>REF(H,DAA)) OR (REF(H,1)<REF(H,DAA) AND C>REF(H,DAA));
EAB:=COUNT(EAA,DAA)=1;
BC1:=REF(H,DAA)/L<1.099;
OUTX:=DAB AND EAA AND EAB AND BC1;
DRAWTEXT(OUTX,L*0.98,'★云破'),COLORWHITE;
B1:=H/MAX(C,O)>1.03 AND L>REF(MAX(C,O),1) AND L=MIN(O,C)
AND (H-MAX(C,O))>(MAX(O,C)-MIN(O,C)) AND REF(C,1)/REF(C,2)<1.09 AND C>O;
B2:=VOL=HHV(VOL,30);
B3:=B1 AND B2;
指尖线:IF(B3,H,REF(H,BARSLAST(B3))),LINETHICK2,COLORRED;
B4:=BARSLAST(B3);
S1:=BETWEEN(B4,3,380);
S2:=L<REF(H,B4) AND H>REF(H,B4);
S3:=COUNT(S2,B4)=1;
S4:=REF(H,B4)/L<1.099 AND REF(C,1)<REF(H,B4);
OUTXG:=S1 AND S2 AND S3 AND S4;
DRAWTEXT(OUTXG,L*0.98,'★指破'),COLORWHITE;
YPXG1:=COUNT(REF(OUTX,1),15)=1 AND REF(C,1)<云顶线 AND C>云顶线 AND
C/REF(C,1)>1.01 AND EVERY(NOT(REF(OUTX,1)),5) AND MA(C,10)>MA(C,20) AND MA(C,20)>MA(C,30) AND MA(C,30)>MA(C,60);
DRAWTEXT(YPXG1,L*0.98,'★云破二次买'),COLORYELLOW;
{云指破副图副图源码如下}
BAA:=O>REF(H,1) AND C<O AND H/O<1.002;
BAB:=VOL=HHV(VOL,30);
BAE:=BAA AND BAB;
DAA:=BARSLAST(BAE);
DAB:=BETWEEN(DAA,3,380);
EAA:=(L<REF(H,DAA) AND H>REF(H,DAA)) OR (REF(H,1)<REF(H,DAA) AND C>REF(H,DAA));
EAB:=COUNT(EAA,DAA)=1;
BC1:=REF(H,DAA)/L<1.099;
OUTX:=DAB AND EAA AND EAB AND BC1;
B1:=H/MAX(C,O)>1.03 AND L>REF(MAX(C,O),1) AND L=MIN(O,C)
AND (H-MAX(C,O))>(MAX(O,C)-MIN(O,C)) AND REF(C,1)/REF(C,2)<1.09 AND C>O;
B2:=VOL=HHV(VOL,30);
B3:=B1 AND B2;
B4:=BARSLAST(B3);
S1:=BETWEEN(B4,3,380);
S2:=L<REF(H,B4) AND H>REF(H,B4);
S3:=COUNT(S2,B4)=1;
S4:=REF(H,B4)/L<1.099 AND REF(C,1)<REF(H,B4);
OUTXG:=S1 AND S2 AND S3 AND S4;
云破:IF(OUTX,1,0),COLORWHITE;
DRAWTEXT(云破,0.5,'云破买'),COLORWHITE;
指破:IF(OUTXG,1,0),COLORRED;
DRAWTEXT(指破,0.5,'指破买'),COLORRED;
ABC:=O>REF(H,1) AND C<O AND H/O<1.01;
ABD:=VOL=HHV(VOL,30);
XGD:=ABC AND ABD;
云顶线:=IF(XGD,H,REF(H,BARSLAST(XGD)));
云破二次买:=COUNT(REF(OUTX,1),15)=1 AND REF(C,1)<云顶线 AND C>云顶线 AND
C/REF(C,1)>1.01 AND EVERY(NOT(REF(OUTX,1)),5) AND MA(C,10)>MA(C,20) AND MA(C,20)>MA(C,30) AND MA(C,30)>MA(C,60);
云二买:IF(云破二次买,1,0),COLORYELLOW;
DRAWTEXT(云二买,0.5,'云二买'),COLORYELLOW;
