涨停天数:=10;
股票分数:=10;
ZJSZ:=FINANCE(7)*C<=30000000000;
DELL:=NOT(CODELIKE('688'));
{引用自设打分系统和扫雷宝评分:
扫雷宝评分电脑可以，手机不可用，
扫雷宝评分一般大于80朝上。
自设评分，一般在55朝上即可。
以下数据评分，引用自设打分系统。
评分:=SAFESCORE>=股票分数;
以下是自设评分系统:}
DLYZ1:=SUM((WINNER(C)*100),30)/30*0.1;
DLYZ2:=SUM((WINNER(C)*100),20)/20*0.4;
DLYZ3:=SUM((WINNER(C)*100),10)/10*0.3;
DLYZ4:=SUM((WINNER(C)*100),5)/5*0.1;
DLYZ5:=SUM((WINNER(C)*100),3)/3*0.1;
DLYZZ:=DLYZ1+DLYZ2+DLYZ3+DLYZ4+DLYZ5;
赚钱效应:IF(DLYZZ>38,DLYZZ,DLYZZ*1.3),LINETHICK3;
活跃度:IF(SUMBARS(VOL,CAPITAL)<100,100-SUMBARS(VOL,CAPITAL),1),NODRAW;
资产负债率:FINANCE(9),NODRAW;
流通市值:=FINANCE(40)/100000000,NODRAW;
利润同比:=FINANCE(43),NODRAW;
收入同比:=FINANCE(44),NODRAW;
{不要改动代码，否则引起变动}
ZT:=C=ZTPRICE(REF(C,1),0.1);
FS1:=IF(资产负债率<45,20,0);
FS11:=IF(100>资产负债率>=45,13,1);
FS2:=IF(利润同比>0,15,0);
FS22:=IF(-10<利润同比<=0,7,4);
FS3:=IF(收入同比>=0,15,0);
FS33:=IF(-10<收入同比<0,7,4);
FS4:=IF(赚钱效应>50,15,12);
FS5:=IF(活跃度>50,15,12);
FS6:=IF(COUNT(ZT,20)>=1,10,7);
JISUAN:=FS1+FS2+FS3+FS4+FS5+FS6+FS11+FS22+FS33;
分数值:IF(JISUAN<100,JISUAN,100),NODRAW;
{具体标记分数，以及结构，价格，位置，涨停，
综合来判断个股走势及当前位置。突破为主的小三浪。}
MA11:=MA(CLOSE,11);
MA36:=MA(CLOSE,36);
MA7:=MA(CLOSE,7);
MA4:=MA(CLOSE,4);
XJC:=CROSS(MA4,MA7);
XSC:=CROSS(MA7,MA4);
JCZQS:=BARSLAST(CROSS(MA11,MA36));
MONEYGS:=COUNT(XJC,JCZQS)+COUNT(XSC,JCZQS);
ZT1:=C=ZTPRICE(REF(C,1),0.1);
TJ8:=COUNT(ZT1,40)>=涨停天数;
TJ0:=MONEYGS=3 OR MONEYGS=2 ;
TJ1:=COUNT(CROSS(MA11,MA36),20)>=1 AND C>3 AND C<40;
TJ22:=MACD.DIF>=-0.10;
TJ2:=MACD.DIF>0 AND MACD.DEA>=0;
TJ33:=COUNT((MACD.MACD>0),20)>=13;
TJ44:=COUNT(MACD.DEA>0 AND REF(MACD.DEA,1)<0,20)>=1;
TJ5:=XJC OR XSC;
XG1:=TJ0 AND TJ1 AND TJ2 AND TJ44 AND TJ5 AND ZJSZ AND DELL AND 分数值>=股票分数 AND TJ8,NODRAW ;
XG2:=TJ0 AND TJ1 AND TJ22 AND TJ33 AND TJ5 AND ZJSZ AND DELL AND 分数值>=股票分数 AND TJ8,NODRAW ;
XG3:=MONEYGS>=2 AND MACD.MACD>0 AND MACD.DEA>0 AND REF(MACD.DEA,1)<0 AND ZJSZ AND DELL AND 分数值>=股票分数 AND TJ8,NODRAW ;
XG:XG1 OR XG2 OR XG3;
DRAWTEXT_FIX(ISLASTBAR,0,0,0,HYBLOCK);
DRAWTEXT_FIX(ISLASTBAR,0,0.15,0,GNBLOCK);
DRAWTEXT_FIX(ISLASTBAR,0,0.30,0,FGBLOCK);
