指标主要用于识别强势涨停股和主升浪机会,操作策略如下:
涨停识别:
普通涨停(10%):连续2-5天涨停标记
创业板涨停(20%):连续2-3天涨停标记
5日内出现3次涨停标记为"五日三板"
涨幅筛选:
5日/10日/20日/40日涨幅超25%/40%/60%/80%
5日均线上穿且保持上升趋势
活跃股池:
包含连续涨停/创业板涨停/高涨幅股票
需同时满足5日、10日均线多头排列
最终信号(SG):
流通市值大于60亿
非ST/*ST股票
处于主升浪阶段(活跃池+均线多头)
操作建议:当出现SG信号时,可重点关注量能配合情况;异动池(非主升浪涨停股)需谨慎参与,适合短线高手操作。注意创业板涨停标准(20%)与主板不同。
{主图源码}
N:=350;
ZF:=1.03;
K25:=20;
科创业板:=IF(INBLOCK('创业板') OR INBLOCK('科创板'),1,0);
深圳股:=IF(INBLOCK('深证A股') AND 科创业板=0,1,0);
涨停价:=IF(科创业板=1,ZTPRICE(REF(CLOSE,1),0.2),ZTPRICE(REF(CLOSE,1),0.1));
{-----------涨跌停加强标示--------------}
DRAWKLINE(H,O,L,C);
{涨停价:=ZTPRICE(REF(CLOSE,1),0.1);}
ZT:= C=涨停价;
创涨停价:=ZTPRICE(REF(CLOSE,1),0.2);
三涨停价:=ZTPRICE(REF(CLOSE,1),0.3);
涨停:=C=涨停价 OR C=创涨停价 OR C=三涨停价 ;
跌停价:=DTPRICE(REF(CLOSE,1),0.1);
跌停:= C=跌停价;
地天板:= L=跌停价 AND C=涨停价;
STICKLINE(涨停,O,C,2,0),COLOR00FFFF;
STICKLINE(跌停,C,O,2,0),COLOR00FF00;
STICKLINE(地天板,C,O,1,0),COLORFF00FF;
STICKLINE((H=涨停价 OR H=创涨停价) AND H>C,H,H,1,-1),COLOR00FFFF;
STICKLINE((H=涨停价 OR H=创涨停价) AND H>C,O,C,0.5,-1),COLOR00FFFF;
STICKLINE((L=跌停价) AND L<C,L,L,1,-1),COLOR00FF00;
{DRAWTEXT(C!=INDEXC AND ABS(1- C/REF(C,1))>0.020,L-0.05,'*'),COLORFF8000;}
{----------入龙门+高标启动 信号加强------------------}
涨停失败:=COUNT(涨停价=H AND 涨停价>C,20);
涨停成功:=COUNT(涨停价=C,20);
涨停值:=涨停失败+涨停成功*2;
连板断板:=COUNT(涨停价=C AND REF(涨停价=C,1),5) AND NOT(涨停价=C);
十日线校对:=NOT(MA(C,10)<REF(MA(C,10),1) AND REF(MA(C,10),2)>REF(MA(C,10),1));
强势多板:=(涨停值>3 OR 连板断板) AND 十日线校对;
龙门池:=REF(强势多板,1) AND 涨停价=C;
龙门1:=龙门池 AND 涨停价=C AND NOT(REF(涨停价=C,1));
龙门2:=REF(龙门1,1) AND 涨停价=C;
龙门3:=REF(龙门2,1) AND 涨停价=C;
DRAWTEXT(龙门1 AND V>REF(V,1),LOW*0.965,'放1'),COLOR00FF00;
DRAWTEXT(龙门1 AND V<REF(V,1),LOW*0.965,'缩1'),COLOR00FF00;
DRAWTEXT(龙门2 AND V>REF(V,1),LOW*0.965,'放2'),COLOR00FFFF;
DRAWTEXT(龙门2 AND V<REF(V,1),LOW*0.965,'缩2'),COLOR00FFFF;
DRAWTEXT(龙门3 AND V>REF(V,1),LOW*0.965,'放3'),COLORFF00FF;
DRAWTEXT(龙门3 AND V<REF(V,1),LOW*0.965,'缩3'),COLORFF00FF;
竞价:(O-REF(C,1))/REF(C,1)*100,NODRAW;
{开盘幅度:IF(REF(ZT,1) AND CURRBARSCOUNT<=N-1,(O-REF(C,1))/REF(C,1)*100,0),NODRAW;}
{均溢价:SUM(开盘幅度,N)/涨停数,NODRAW,COLOR00FFFF;}
{暴额:HHV(AMO,100)/100000000,COLORFFFF00,NODRAW;}
{--------属性特征强化标记-----------}
{连板周期:=BARSLAST(COUNT(C=涨停价,2)=2);}
{连板调整日:=连板周期,NODRAW,COLOR00FF00;}
{DRAWTEXT(连板调整日=6,LOW*0.955,'⑥'),COLOR00FFFF;}
{DRAWTEXT(连板调整日=7,LOW*0.955,'⑦'),COLOR00FFFF;}
{DRAWTEXT(连板调整日=8,LOW*0.955,'⑧'),COLOR00FFFF;}
{涨停调整缩量:=NOT(ZT) AND NOT(跌停) AND BARSLAST(COUNT(ZT,1)=1)<25 AND V=LLV(V,6) AND MACD.DIF>-0.1 AND MACD.DEA>-0.1 AND MA(C,20)*0.98<C ;}
{DRAWTEXT(涨停调整缩量 AND V<REF(MA(V,60),1),LOW*0.995,'。'),COLORFF00FF;}
涨停封住:= C=ZTPRICE(REF(C,1),0.1);
达到涨停:= H=ZTPRICE(REF(C,1),0.1);
二连涨停:=涨停封住 AND REF(涨停封住,1);
三连涨停:=涨停封住 AND REF(二连涨停,1);
四连涨停:=涨停封住 AND REF(三连涨停,1);
五连涨停:=涨停封住 AND REF(四连涨停,1);
五日三板:=COUNT(COUNT(达到涨停,5)>2,5)>0;
创涨停:=C=ZTPRICE(REF(C,1),0.2);
达到创涨停:=H=ZTPRICE(REF(C,1),0.2);
创2板:=创涨停 AND REF(创涨停,1);
创3板:=创涨停 AND REF(创2板,1);
五日二板:=COUNT(COUNT(达到创涨停,5)>1,5)>0;
五日25:=(C*100/REF(C,5) -100) >25;
十日40:=(C*100/REF(C,10) -100) >40;
二十日60:=(C*100/REF(C,20) -100) >60;
四十日80:=(C*100/REF(C,40) -100) >80;
涨幅活跃:=五日25 OR 十日40 OR 二十日60 OR 四十日80;
条件5:=(MA(C,5)<C OR REF(MA(C,5)<C,1) ) AND MA(C,5)>=REF(MA(C,5),1);
条件10:=(MA(C,10)<C OR REF(MA(C,10)<C,1) ) AND MA(C,10)>=REF(MA(C,10),1);
活跃池:= COUNT(三连涨停,10)>0 OR 五日三板 OR COUNT(创2板,10)>0 OR 五日二板 OR 涨幅活跃;
活跃主升:= 活跃池 AND 条件10 AND 条件5 AND MA(C,5)>MA(C,10);
活跃震荡:= 活跃池 AND NOT(活跃主升) AND 条件10;
异动池:= NOT(活跃池) AND COUNT(涨停封住,10)>0;
{-----均线系统强化标记---------------------------}
MA5:MA(C,5),COLORFFFFFF,LINETHICK1;
{IF(MA(C,5)<REF(MA(C,5),1) AND REF(MA(C,5),2)>REF(MA(C,5),1) AND REF(MA(C,5),3)>REF(MA(C,5),2),MA5,DRAWNULL),COLORGREEN,LINETHICK1;}
MA10:MA(C,10),COLOR00FFFF,LINETHICK1;
IF( 活跃主升 ,MA10,DRAWNULL),COLORFF00FF,LINETHICK2;
IF( MA(C,10)<REF(MA(C,10),1) ,MA10,DRAWNULL),COLORGREEN,LINETHICK4;
IF( MA(C,10)>C AND REF(MA(C,10)>C,1),MA10,DRAWNULL),COLORGREEN,LINETHICK4;
总市值: FINANCE(1)*C/100000000,NODRAW;
五日:C*100/REF(C,5) -100,NODRAW,COLOR00FFFF;
十日:C*100/REF(C,10) -100,NODRAW,COLOR00FFFF;
二十日:C*100/REF(C,20) -100,NODRAW,COLOR00FFFF;
四十日:C*100/REF(C,40) -100,NODRAW,COLOR00FFFF;
最大额:HHV(AMO,5)/100000000,NODRAW,COLOR0000FF;
{涨停活跃主升副图源码}
涨停封住:= C=ZTPRICE(REF(C,1),0.1);
达到涨停:= H=ZTPRICE(REF(C,1),0.1);
二连涨停:=涨停封住 AND REF(涨停封住,1);
三连涨停:=涨停封住 AND REF(二连涨停,1);
四连涨停:=涨停封住 AND REF(三连涨停,1);
五连涨停:=涨停封住 AND REF(四连涨停,1);
五日三板:=COUNT(COUNT(达到涨停,5)>2,5)>0;
创涨停:=C=ZTPRICE(REF(C,1),0.2);
达到创涨停:=H=ZTPRICE(REF(C,1),0.2);
创2板:=创涨停 AND REF(创涨停,1);
创3板:=创涨停 AND REF(创2板,1);
五日二板:=COUNT(COUNT(达到创涨停,5)>1,5)>0;
五日25:=(C*100/REF(C,5) -100) >25;
十日40:=(C*100/REF(C,10) -100) >40;
二十日60:=(C*100/REF(C,20) -100) >60;
四十日80:=(C*100/REF(C,40) -100) >80;
涨幅活跃:=五日25 OR 十日40 OR 二十日60 OR 四十日80;
条件5:=(MA(C,5)< C OR REF(MA(C,5)< C,1) ) AND MA(C,5)>=REF(MA(C,5),1);
条件10:=(MA(C,10)< C OR REF(MA(C,10)< C,1) ) AND MA(C,10)>=REF(MA(C,10),1);
活跃池:= COUNT(三连涨停,10)>0 OR 五日三板 OR COUNT(创2板,10)>0 OR 五日二板 OR 涨幅活跃;
活跃主升:= 活跃池 AND 条件10 AND 条件5 AND MA(C,5)>MA(C,10);
异动池:= NOT(活跃主升) AND (COUNT(达到涨停,10)>0 OR COUNT(达到创涨停,10)>0);
SG: FINANCE(42)>60 AND 活跃主升 AND NOT(IF(NAMELIKE('ST'),1,0)) AND NOT(IF(NAMELIKE('*ST'),1,0));
{量学副图源码}
绿低量:=10;
蓝低量:=50;
灰低量:=100;
H_L:=0.1*CONST(HHV(VOL,240));
{MAV10:MA(V,10),COLORYELLOW;}
VVOL:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);{模拟量}
STICKLINE(CURRBARSCOUNT=1 AND PERIOD=5,VVOL,0,1,-1),COLOR00C0C0;
量:VOL,VOLSTICK,COLORLIGRAY;
换手: VOL*10000/FINANCE(7),NODRAW,COLORGREEN; {DYNAINFO(37)*100}
全换手周期: SUMBARS(V,CAPITAL),NODRAW,COLORLIGREEN;{求完全换手到现在的周期数}
量比: V/REF(MA(V,5),1),COLORBROWN,NODRAW;
几倍: V/REF(V,1),COLORYELLOW,NODRAW;
倍数:=1.9;
倍量: VOL>=REF(V,1)*倍数 AND (IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
倍缩: REF(V,1)>=VOL*倍数,COLORMAGENTA,NODRAW;
平量: RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: VOL=LLV(VOL,绿低量) AND BARSCOUNT(V)>=绿低量,COLORGREEN,NODRAW;
低量50: VOL=LLV(VOL,蓝低量) AND BARSCOUNT(V)>=蓝低量,COLORBLUE,NODRAW;
地量: VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,COLORGRAY,NODRAW;
V1:=VOL*0.95;{图标位置}
V2:=VOL*0.85;
STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;
STICKLINE(低量50,0,V2,1,0),COLORBLUE;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(倍缩,0,V*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O AND C>REF(C,1),0,V1,0,0),COLORRED;{假阴柱}
真阳或假阴:=C>O OR C>REF(C,1);
收阳:= REF(真阳或假阴,3);
倍量1:=REF(倍量,3);
高量:=REF(V,3)>=HHV(V,7);
三日不破:= LLV(C,3)>=REF(L,3);
价升:=COUNT(C>=REF(C,1),3)=3;{收盘价逐升}
量缩:=COUNT(V<=REF(V,1),3)=3;
连阳:= COUNT(真阳或假阴,3)=3;
倍量将军柱:= 倍量1 AND 三日不破 AND 收阳;
高量将军柱:= 高量 AND 三日不破 AND 收阳;
将军柱:= 倍量将军柱 OR 高量将军柱;
黄金柱:= 将军柱 AND 价升 AND 量缩 AND 连阳 ;{标准黄金柱}
STICKLINE(黄金柱,0.3*V,0.7*V,1,0),COLORRED; {红柱}
DRAWICON(黄金柱,V*1.5,1);
V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),V+3*H_L,'地量群'),COLORGRAY;
长阴短柱:=C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9;
DRAWTEXT(长阴短柱 ,V+1.6*H_L,'!'),COLORLICYAN;