指标名称：综合资金攻击分时系统
指标类型：分时图技术指标
核心功能与用法：
1. 资金流向监控：
资金流入（红柱）：显示当日开盘后，所有上涨分钟对应的成交量之和。红柱越高，代表上涨时主动买入的资金量越大。
资金流出（绿柱）：显示当日开盘后，所有下跌分钟对应的成交量之和。绿柱越高，代表下跌时主动卖出的资金量越大。
资金出入（红绿柱）：是资金流入与流出的净额，以红绿柱线显示。红柱表示净流入，绿柱表示净流出。
资金流量（白线）：与“资金出入”数值相同，以连续曲线形式展示净资金流的趋势。
资金比（青线）：资金净流入额占当日总成交额的比例，用于衡量资金流入的强度。
2. 攻击力度分析：
攻击量A（蓝线，数值）：结合换手率（HSL）加权计算的上涨攻击成交量。
攻击量B（绿线，数值）：结合换手率（HSL）加权计算的下跌攻击成交量。
攻击流量（红绿柱）：攻击量A与B的净额，反映经过加权处理后的主力攻击性资金流向。
攻击线（黄线）：攻击流量的曲线形式。
攻击比（红线）：攻击流量占当日总成交额的比例，反映攻击性资金的强度。
3. 多空状态与信号：
开始攻击（黄色信号柱）：当“攻击流量”由负转正上穿零轴，且价格或资金流表现强势时触发，提示可能开始向上攻击。
开始攻击量（紫色信号柱）：在“开始攻击”条件基础上，增加了成交量显著放大的要求，信号强度更高。
分时突破（白色信号柱及文字）：当价格在特定时段（上午10:00或11:00）突破前期高点且放量时标记，提示分时图上的关键突破点。
4. 主力散户博弈线：
主力线（洋红色点划线）、散户线（绿色粗线）、起动线（黄色点线）：这三条线是基于价格与动态成本均价（VBNH）的比值计算出的指数平滑移动平均线。用于判断资金属性（主力或散户）的动向。
“★迹”信号（青色柱）：当“主力线”上穿“散户线”时发出，提示主力可能开始活跃。
“追击”信号（红色文字）：当股价上穿“散户线”，且“散户线”位于“分时均价线”之上时出现，提示追击机会。
“小心/走弱”信号（绿色文字）：当“散户线”上穿“主力线”或“大户线”时出现，提示行情可能走弱。
5. 支撑阻力与操作提示：
阻力（绿线）、支撑（洋红线）：根据当日动态高低点计算的理论阻力和支撑位。
“–买入”信号：当股价下探触及或跌破“支撑”线时提示。
“–出货”信号：当股价上涨触及或突破“阻力”线时提示。
6. 机构资金统计：
在副图或图形固定位置，以文字形式显示：
机构买/卖比例：基于大单成交额（成交额/8>20万）统计的机构买卖占比。
机构净买比例：机构净买入占总大单成交的比例。
在图形右上角固定位置显示：
现手买/卖（万）：当前买一/卖一挂单的即时金额估算。
买卖差（万）：买一与卖一挂单金额的差值。
买/卖占比：买一/卖一挂单金额占总挂单金额的比例。
7. 涨停潜力与主升信号：
“可能涨停”信号（洋红文字）：当“起动线”上穿1.01阈值时，在低价区域提示。
“-主攻”信号（黄色文字及图标）：当“主攻线”>“大户线”>“散户线”，且均线呈多头排列，“主攻线”创近期新高并上穿1.003时触发，提示主力进攻。
“–拉升/–冲涨停”信号（青色/亮洋红文字）：当“主攻线”继续强势上穿更高阈值（1.02， 1.04）时发出，提示拉升或冲击涨停阶段。
使用场景：
本指标适用于沪深A股的分时图分析，旨在实时监控当日资金流向、多空攻击力度、主力散户行为以及捕捉盘中可能的启动、突破、拉升和风险信号。适合短线交易者用于判断盘中买卖时机、感知市场情绪和主力意图。使用者应结合K线形态、大盘环境及个股基本面进行综合决策。
资金流入:=SUM(IF(C>REF(C,1),V,0),FROMOPEN),STICK,COLORRED;
资金流出:=-SUM(IF(C<REF(C,1),V,0),FROMOPEN),STICK,COLOR00FF00;
资金出入:=资金流入+资金流出,COLORSTICK;
资金流量:=资金出入,COLORFFFFFF,LINETHICK1;
资金比:=资金出入/SUM(V,FROMOPEN)*100,COLOR00FFFF,LINETHICK1;
资金流量比:=IF(资金比>=0,(资金比+100)/2,100-ABS((资金比-100)/2));
增强流量比:=IF(资金流量比>50,资金流量比,50);
HSL:=V/CAPITAL*100;
攻击量:=((HSL*0.50+(REF(HSL,1)*0.33))+(REF(HSL,2)*0.17))*SUM(C,FROMOPEN)/FROMOPEN;
攻击量A:=SUM(IF(C>REF(C,1),攻击量*V,0),FROMOPEN),COLOR0000FF,LINETHICK0;
攻击量B:=-SUM(IF(C<REF(C,1),攻击量*V,0),FROMOPEN),COLOR00FF00,LINETHICK0;
攻击流量:=攻击量A+攻击量B,COLORSTICK;
攻击线:=攻击流量,COLORYELLOW,LINETHICK1;
攻击比:=攻击流量/SUM(V,FROMOPEN)*100,COLORRED,LINETHICK1;
资金攻击度:=IF(攻击比>0,(攻击比+50),100-ABS((攻击比-50)));
攻击度限制:=IF(资金攻击度>100,100,IF(资金攻击度<0,0,资金攻击度));
增强攻击度:=IF(资金攻击度>50,资金攻击度,50);
开始攻击:=CROSS(攻击流量,0) AND (C>REF(C,2) OR (资金流量>0 AND 资金流量>攻击流量));
开始攻击量:=CROSS(攻击流量,0) AND C>REF(C,2) AND V>LLV(V,3)*3;
Q:=250;
高点:=HHV(C,Q);
低点:=LLV(C,Q);
最高:=CONST(高点),NODRAW;
最低:=CONST(低点),NODRAW;
轴差:=最高-最低;
中价轴:=(最高+最低)/2;
HL3:=(100-0)/2*1.3;
HL4:=(100-0)/1*1.3;
中间价轴:=(50-HL3)*轴差/HL4+中价轴;
平安轴:=(中价轴+中间价轴)/2;
BGTYU:=1;
GHYJKU:=BETWEEN((CLOSE*BGTYU)/(SUM(AMOUNT,BARSCOUNT((CLOSE*BGTYU)))/SUM(VOL*100,BARSCOUNT((CLOSE*BGTYU)))),0.95,1.05);
VBNH:=IF(GHYJKU=0,MA((CLOSE*BGTYU),BARSCOUNT((CLOSE*BGTYU))),(SUM(AMOUNT,BARSCOUNT((CLOSE*BGTYU)))/SUM(VOL*100,BARSCOUNT((CLOSE*BGTYU)))));
起动线:=EXPMA((CLOSE/VBNH),20)*1,COLORYELLOW,POINTDOT;
主力线:=EXPMA((CLOSE/VBNH),60)*1,COLORMAGENTA,LINETHICK2;
散户线:=EXPMA((CLOSE/VBNH),120)*1,COLORGREEN,LINETHICK2;
限制起动线:=起动线*中间价轴;
限制主力线:=主力线*中间价轴;
限制散户线:=散户线*中间价轴;
主散MIN:=MIN(限制主力线,限制散户线);
主力:限制主力线,DOTLINE,COLORFF00FF,LINETHICK1;
分时均价线:=SUM(C*V,240)/SUM(V,240),DOTLINE,COLORFFFFFF,LINETHICK1;
追击涨停:=限制散户线>分时均价线 AND CROSS(C,限制散户线);
拉升量:=IF(C>REF(C,1),VOL,0);
昨拉升最高值:=CONST(HHV(REF(拉升量,1),FROMOPEN)),LINETHICK1,COLORMAGENTA;
今拉升最高值:=CONST(HHV(拉升量,FROMOPEN)),COLORYELLOW,NODRAW;
攻击力度:=今拉升最高值/昨拉升最高值,NODRAW;
TT:=BARSCOUNT(C);
均价黄:=SUM(C*V,TT)/SUM(V,TT);
量两步:=MA(V,5)>REF(MA(V,5),1) AND REF(MA(V,5),1)>REF(MA(V,5),2);
价两步:=C>=REF(C,1) AND REF(C,1)>REF(C,2);
价上岗量破5:=C>均价黄 AND V>MA(V,5);
量起爆:=V>=REF(V,1)*1;
价创新高:=C>=HHV(C,0);
量创新高:=V>=HHV(V,0);
对昨日涨幅:=(C/DYNAINFO(3)-1)*100<=2.50;
每日一点:=量两步 AND 价两步 AND 价上岗量破5 AND 量起爆 AND 价创新高 AND 量创新高 AND 对昨日涨幅;
TA:=BARSLAST(TIME=100000);
TC:=REF(HHV(C,0),TA+1);
TV:=REF(HHV(V,0),TA+1);
ZF:=C/DYNAINFO(3)<1.05;
XG1:=CROSS(C,TC) AND V>TV AND ZF;
TA1:=BARSLAST(TIME=110000);
CC1:=REF(HHV(C,0),TA1+1);
VV1:=REF(HHV(V,0),TA1+1);
ZF1:=CC1/DYNAINFO(3)<1.05;
XG2:=CROSS(C,CC1) AND V>VV1 AND ZF1;
突破:=XG1 OR XG2;
STICKLINE(FILTER(突破=1,15),最低+轴差*0.60,最低,1,0),COLORWHITE;
DRAWICON(FILTER(突破=1,15),最低+轴差*0.60,17);
DRAWTEXT(FILTER(突破=1,15),最低+轴差*0.60,'∠分时突破'),COLORWHITE;
STICKLINE(FILTER(开始攻击量=1,15),最低+轴差*0.45,最低,1,0),COLORMAGENTA;
STICKLINE(FILTER(开始攻击=1,30),最低+轴差*0.30,最低,1,0),COLORYELLOW;
STICKLINE(CROSS(EXPMA((CLOSE/VBNH),60),EXPMA((CLOSE/VBNH),120)),最低+轴差*0.15,最低,1,0),COLORCYAN;
DRAWICON(FILTER(开始攻击量=1,15),最低+轴差*0.45,24);
DRAWICON(FILTER(开始攻击,30),最低+轴差*0.30,30);
DRAWTEXT(FILTER(开始攻击量=1,15),最低+轴差*0.45,'∠攻击量'),COLORMAGENTA;
DRAWTEXT(FILTER(开始攻击,30),最低+轴差*0.30,'开始攻'),COLORYELLOW;
DRAWTEXT(FILTER(CROSS(EXPMA((CLOSE/VBNH),60),EXPMA((CLOSE/VBNH),120)),30),最低+轴差*0.15,'★迹'),COLORCYAN;
DRAWICON(FILTER(CROSS(起动线,1.01),30),限制散户线,17);
DRAWTEXT(FILTER(CROSS(起动线,1.01),30),最低,'可能涨停'),COLORMAGENTA;
DRAWTEXT(FILTER(追击涨停,30),分时均价线+(限制散户线-分时均价线)/2,'追击'),COLORRED;
H1:=MAX(DYNAINFO(3),DYNAINFO(5));
L1:=MIN(DYNAINFO(3),DYNAINFO(6));
P1:=H1-L1;
阻力:=L1+P1*7/8,COLORGREEN;
支撑:=L1+P1*0.5/8,COLORMAGENTA;
DRAWTEXT(CROSS(支撑,C),C,'--买入'),COLORFF00FF;
DRAWTEXT(CROSS(C,阻力),C,'--出货'),COLOR70DB93;
XX:=SUM(AMOUNT,BARSCOUNT(CLOSE))/SUM(V*100,BARSCOUNT(CLOSE));
主攻:=EXPMA(CLOSE/XX,20);
大户:=EXPMA(CLOSE/XX,60);
散户:=EXPMA(CLOSE/XX,120);
AA:=主攻>大户 AND 主攻>1.003 AND 大户>散户 AND C>EXPMA(C,20) AND EXPMA(C,10)>EXPMA(C,20) AND EXPMA(C,20)>EXPMA(C,60);
DRAWICON(主攻>大户 AND 大户>散户 AND C>EXPMA(C,20) AND EXPMA(C,10)>EXPMA(C,20) AND EXPMA(C,20)>EXPMA(C,60) AND 主攻=HHV(主攻,30) AND CROSS(主攻,1.003),C,38);
DRAWTEXT(主攻>大户 AND 大户>散户 AND C>EXPMA(C,20) AND EXPMA(C,10)>EXPMA(C,20) AND EXPMA(C,20)>EXPMA(C,60) AND 主攻=HHV(主攻,30) AND CROSS(主攻,1.003),C*0.999,'-主攻'),COLORYELLOW;
DRAWTEXT(CROSS(主攻,1.02),C*0.999,'--拉升'),COLORCYAN;
DRAWTEXT(CROSS(主攻,1.04),C*0.999,'--冲涨停'),COLORLIMAGENTA;
DRAWTEXT(CROSS(散户,主攻),C*0.9995,'--小心'),COLORGREEN;
DRAWTEXT(CROSS(散户,大户),C*0.9995,'--走弱'),COLORGREEN;
成交额:=V*C/100;
A2:=SUM((IF(((成交额/8>20) AND (CLOSE>(REF(CLOSE,1)))),成交额,0)),0);
A3:=SUM((IF(((成交额/8>20) AND (CLOSE<(REF(CLOSE,1)))),成交额,0)),0);
A6:=(A2+A3);
A7:=IF((ISLASTBAR),((100*A2)/A6),0);
A8:=IF((ISLASTBAR),((100*A3)/A6),0);
DD1:=1;
AAA1:=STRCAT(STRCAT('机构买 = ',CON2STR((100*A2)/A6,0)),'%');
AAA2:=STRCAT(STRCAT('机构卖 = ',CON2STR((100*A3)/A6,0)),'%');
AAA3:=STRCAT(STRCAT('机构总买 = ',CON2STR((100*(A2-A3))/A6,0)),'%');
DRAWTEXT_FIX(DD1=1,0,0.89,0,AAA1),COLOR00FFFF;
DRAWTEXT_FIX(DD1=1,0,0.945,0,AAA2),COLOR00FF00;
现手买:=DYNAINFO(9)*DYNAINFO(7)*100/10000;
现手卖:=DYNAINFO(10)*DYNAINFO(7)*100/10000;
合:=ABS(现手买)+ABS(现手卖);
差:=ABS(现手买)-ABS(现手卖);
MPB1:=ABS(现手买)/合*100;
MPB2:=ABS(现手卖)/合*100;
DRAWTEXT_FIX(1,0.8,0.88,0,STRCAT(STRCAT('',CON2STR(现手买,2)),'万')),COLOR0000FF;
DRAWTEXT_FIX(1,0.68,0.88,0,STRCAT(STRCAT('',CON2STR(现手卖,2)),'万')),COLOR00FF00;
DRAWTEXT_FIX(ISLASTBAR AND(差)>0,0.755,0.98,0,STRCAT(' ',STRCAT(CON2STR(差,2),'万'))),COLOR00FFFF;
DRAWTEXT_FIX(ISLASTBAR AND(差)<0,0.755,0.98,0,STRCAT(' ',STRCAT(CON2STR(差,2),'万'))),COLOR00FF00;
DRAWTEXT_FIX(ISLASTBAR AND(差)=0,0.755,0.98,0,STRCAT(' ',STRCAT(CON2STR(差,2),'万'))),COLOR80FFFF;
DRAWTEXT_FIX(1,0.935,0.97,0,STRCAT(STRCAT(' ',CON2STR(MPB2,2)),'%')),COLOR00FF00;
DRAWTEXT_FIX(1,0.585,0.97,0,STRCAT(STRCAT('',CON2STR(MPB1,2)),'%')),COLOR0000FF;
