指标是一个复合型技术分析工具，融合了多种经典指标并进行再加工，主要用于识别趋势、超买超卖以及捕捉买卖信号。其核心构成与用法如下：
1. 核心指标区（主图区域）
CCI通道：基于典型价格计算，并进行了平滑处理。指标在0轴上下方用不同颜色的带状区域填充，直观显示CCI的强弱区域。通常，指标线在+100上方为强势区，在-100下方为弱势区。
RSI与KDJ的归一化处理：将RSI和KDJ的K值通过`(原值-50)5`的公式进行缩放，使其波动范围与CCI大致对齐，便于在同一坐标系下观察多个指标的共振情况。
多指标共振信号：
买入信号：当处理后的RSI趋势线（RR1）金叉且其值与处理后的KDJ趋势线（BB1）、CCI趋势线（CB1）三者同时低于-100时，在主图下方（-200位置）标记“买入”图标。
卖出信号：当处理后的RSI趋势线死叉且CCI趋势线（CB1）高于100时，在主图上方（200位置）标记“卖出”图标。
2. 量价与趋势动能区（中部区域）
“阶段底部”柱状图：指标综合了RSI、ADX（平均趋向指数）和威廉指标（W%R），用于衡量市场动能和潜在转折点。
红色粗柱：当“阶段底部”值小于0时显示，通常表示空头动能强劲或处于下跌趋势中。
橙色细柱：当“阶段底部”值大于等于0时显示，通常表示多头动能开始恢复或处于上升趋势中。
“趋势线”与绿色警示：绘制“阶段底部”的1周期最低值。当此“趋势线”数值突破230时，会显示一根绿色粗柱，这可能是一个强烈的趋势过热或即将反转的警示信号。
“拉升！”信号：结合了放量（成交量突破5、10、60日均量）、均线多头排列（5、8、25日均线在60日均线上方）以及CCI上穿其均线等多重条件，在满足时标记“拉升！”文字，提示可能出现强势上涨。
3. 辅助指标与资金流向区（下部及叠加区域）
CCI平滑线（BB线）：对原始CCI进行短期指数平滑（2周期），作为CCI的快速信号线。其与原始CCI的交叉（金叉/死叉）以及突破关键位置（如-100、150）会触发底部或顶部图标信号。
主力线与超短线：
主力线：基于27周期内股价位置计算的趋势强度指标。其涨跌用红绿柱状图表示，红色代表主力线上升，绿色代表下降。
超短线：对“主力线”进行二次平滑和标准化处理，用于捕捉更短期的波动机会。
股价准备启动：当“超短线”指标上穿阈值3时，标记为“股价准备启动”，提示短期可能启动。
庄家秘密进/撤：通过多周期价格均线的复杂计算，得出两条方向线。红色线（庄家秘密进）代表资金流入推动力，绿色线（庄家秘密撤）代表资金流出压力。
BIAS（乖离率）通道：
计算了13日和27日的乖离率及其移动平均。
见底信号：当27日乖离率的均线低于-15时，标记“见底”信号。
短线/中线动能柱：
分别计算股价相对于13日和4日均线的偏离度作为“短线”和“中线”。
对它们进行平滑后，用红/青色柱状图表示“短线”动能的强弱变化，用黄/青色柱状图表示“中线”动能的强弱变化。柱体的颜色变化（如红变青、黄变红）反映了短期或中期动能的加速或衰减。
使用要点总结：
指标信息密集，应侧重于多指标共振。理想的买入机会通常出现在：主图出现“买入”图标、中部“阶段底部”出现橙色柱且“趋势线”无绿色警示、下部“庄家秘密进”红线上扬、“见底”信号出现，且动能柱显示多头力量增强时。卖出或警示信号则相反。由于信号频繁，需结合K线形态与大盘环境进行过滤。
N:=9;M:=14;N1:=6;
TYP := (HIGH + LOW + CLOSE)/3;
CC1:=(TYP-MA(TYP,M))/(0.015*AVEDEV(TYP,M)),COLORFF00FF;
C1:=SMA(CC1,3,1);
C2:=SMA(C1,3,1);
C3:=3*C1-2*C2;
CB1:=EMA(C3,5);
CB2:=REF(CB1,1);
DRAWBAND(CC1,RGB(220,50,100),100,RGB(100,150,72));
DRAWBAND(CC1,RGB(220,50,100),100,RGB(100,80,220));
STICKLINE(C>1,100,-100,5,0),COLORGRAY;
CCI:CC1,COLORFF00FF;
LC := REF(CLOSE,1);
RSI1:=SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*100;
RSI:(RSI1-50)*5,LINETHICK2,COLORYELLOW;
R1:=SMA(RSI,3,1);
D1:=SMA(R1,3,1);
J1:=3*R1-2*D1;
RR1:=EMA(J1,5);
RR2:=REF(RR1,1);
RR:=RR1>RR2;
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,3,1);
K1:(K-50)*5,COLORFFFF00;
K2:=SMA(K1,3,1);
D2:=SMA(K2,3,1);
J2:=3*K2-2*D2;
BB1:=EMA(J2,5);
BB2:=REF(BB1,1);
买入:=RR AND NOT(REF(RR,1)) AND (RR1<-100 AND BB1<-100) AND CB1<-100;
DRAWICON(买入,-200,1);
卖出:=REF(RR,1)=1 AND NOT(RR) AND CB1>100;
DRAWICON(卖出,200,2);
LC1:=REF(CLOSE,1);
RSI5:=((SMA(MAX((CLOSE - LC1),0),5,1) / SMA(ABS((CLOSE - LC1)),5,0)) * 100);
RTS3:=SUM(MAX(MAX((HIGH - LOW),ABS((HIGH - REF(CLOSE,1)))),ABS((LOW - REF(CLOSE,1)))),10);
HD:=(HIGH - REF(HIGH,1));
LD:=(REF(LOW,1) - LOW);
DMP:=SUM(IF(((HD > 0) AND (HD > LD)),HD,0),10);
DMM:=SUM(IF(((LD > 0) AND (LD > HD)),LD,0),10);
PDI:=((DMP * 100) / RTS3);
MDI:=((DMM * 100) / RTS3);
ADX:=MA(((ABS((MDI - PDI)) / (MDI + PDI)) * 100),5);
AV:=(RSI5 + ADX);
DXR:=(((ADX + REF(ADX,5)) / 2) + RSI5);
0,COLORFF00FF;
WR10:=((100 * (HHV(HIGH,10) - CLOSE)) / (HHV(HIGH,10) - LLV(LOW,10)));
NEWVOL:=(RSI5 - WR10);
阶段底部:=(AV + NEWVOL);
STICKLINE((阶段底部 >= 0),0,阶段底部,0.3,1),LINETHICK2,COLORCC6600;
STICKLINE((阶段底部 < 0),0,阶段底部,0.8,1),LINETHICK6,COLORRED;
趋势线:LLV(阶段底部,1),COLORFFFFFF;
STICKLINE((趋势线 >230 ),250,趋势线,0.8,1),LINETHICK6,COLORGREEN;
230,COLORFFFFFF;
VAR1:=(HIGH+LOW+CLOSE)/3;
VAR2:=(VAR1-MA(VAR1,14))/(0.015*AVEDEV(VAR1,14));
150,COLORBLUE;
100;
0;
-100;
-150;
BB: EMA(VAR2,2),LINETHICK2,COLORWHITE;
VAR3:=MA(VOL,5);
VAR4:=MA(VOL,10);
VAR5:=MA(VOL,60);
VAR6:=MA(CLOSE,5);
VAR7:=MA(CLOSE,8);
VAR8:=MA(CLOSE,25);
VAR9:=MA(CLOSE,60);
VARA:=CROSS(VAR2,BB) AND VAR2>80 AND VOL>VAR3 AND VOL>VAR4 AND VOL>VAR5 AND VAR6>VAR9 AND VAR7>VAR9 AND VAR8>VAR9 AND OPEN<VAR6 AND CLOSE>VAR6;
{-股票公式网站 }
DRAWTEXT(VARA,5,' 拉升！'),COLORYELLOW;
STICKLINE(VARA,5,-100,3,0),COLORRED;
底部:=CROSS(BB,-100);
DRAWICON(底部,-100,1);
顶部:=CROSS(150,BB);
DRAWICON(顶部,150,2);
VAR11:=3;
VAR21:=(3)*(SMA(((CLOSE - LLV(LOW,27))/(HHV(HIGH,27) - LLV(LOW,27)))*(100),5,1)) - (2)*(SMA(SMA(((CLOSE - LLV(LOW,27))/(HHV(HIGH,27) - LLV(LOW,27)))*(100),5,1),3,1));
股价准备启动:IF(CROSS(VAR21,VAR11),100,0),COLORRED,LINETHICK2;
主力线:3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*
SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1),LINETHICK1,POINTDOT;
超短线:2*(((主力线-LLV(主力线,21))/(HHV(主力线,21)-LLV(主力线,21)))*(4))*(25),LINETHICK2,COLORMAGENTA;
STICKLINE(主力线>REF(主力线,1) ,主力线 ,REF(主力线,1),3 ,0),COLORFF00FF;
STICKLINE(主力线<=REF(主力线,1) ,主力线 ,REF(主力线,1),3 ,0),COLORGREEN;
V1:=(C*2+H+L)/4*1;
V2:=EMA(V1,13)-EMA(V1,34);
V3:=EMA(V2,5);
V4:=2*(V2-V3)*5.5;
庄家秘密撤: IF(V4<=0,V4,0),COLOR00FF00,LINETHICK2;
庄家秘密进: IF(V4>=0,V4,0),COLORRED,LINETHICK2;BIAS1:=MA((CLOSE-MA(CLOSE,13))/MA(CLOSE,13),3)*2,COLORWHITE;
BIAS3:=MA((CLOSE-MA(CLOSE,27))/MA(CLOSE,27),3)*2,COLORFF00FF,LINETHICK2;
见底:IF(BIAS3<-15,10,0),LINETHICK2,COLORRED;短线:(CLOSE-MA(CLOSE,13))/MA(CLOSE,13)*500,LINETHICK0,COLORYELLOW;
中线:(CLOSE-MA(CLOSE,4))/MA(CLOSE,4)*500,LINETHICK0,COLORWHITE;
红柱:SMA(短线,3,1),LINETHICK0,COLOR0000FF;
蓝柱:SMA(中线,3,1),COLORSTICK,COLORFFFF00;
{红柱}
STICKLINE(红柱<REF(红柱,1)AND 红柱>0,0,红柱,1,1),COLORCYAN;
STICKLINE(红柱>REF(红柱,1)AND 红柱>0,0,红柱,1,1),COLORRED;
STICKLINE(蓝柱<REF(蓝柱,1) AND 蓝柱>0,0,蓝柱,1,0),COLOR00FFFF;
{蓝柱}
STICKLINE(红柱>REF(红柱,1)AND 红柱<0,0,红柱,1,0),COLORLIRED;
STICKLINE(红柱<REF(红柱,1)AND 红柱<0,0,红柱,1,1),COLORGREEN;
STICKLINE(蓝柱>REF(蓝柱,1)AND 蓝柱<0,0,蓝柱,1,0),COLORRED;
