指标构成与核心逻辑：
指标是一个复合型交易系统，融合了趋势、动量、超买超卖以及背离分析。其核心围绕两条主线：
1. 长期趋势线：通过计算收盘价的5日指数移动平均与340日指数移动平均的差值（V1），再对其取144日指数移动平均（V2），形成一条长期趋势基准线。V1与V2的关系用于判断市场所处的长期趋势阶段。
2. 短期波动与RSI分析：通过一个27周期的随机摆动指标（V3）和多个周期的RSI指标，捕捉短期超买超卖状态、买卖信号以及顶底背离形态。
主要信号与用法：
趋势与摆动综合信号：
卖出信号：当短期摆动指标V3从高位（98.5）向下交叉，且长期趋势线V1运行在基准线V2之上时，标记“卖”字。这是一个在强势趋势中捕捉短期见顶的信号。
抄底信号：当短期摆动指标V3从低位（5）向上交叉，且长期趋势线V1运行在基准线V2之下时，标记“抄”字。这是一个在弱势趋势中捕捉短期反弹的信号。
RSI指标信号：
短期买卖点：基于一个短周期（N1=5）的RSI。
买点：当该RSI上穿50中轴时，显示“买”字并绘制红色柱状线。
卖点：当该RSI上穿80超买线时，显示“卖”字并绘制橙色柱状线。
背离分析：
顶背离：当价格创出近期新高，而RSI指标未能同步新高时，在RSI曲线上方标记“顶”字并绘制白色连线。提示上涨动能减弱。
底背离：当价格创出近期新低，而RSI指标未能同步新低时，在RSI曲线下方标记“底”字并绘制白色连线。提示下跌动能减弱。
资金饱和度与黑马跟踪：
资金饱和度：通过计算成交额均线的布林带位置，以柱状图形式显示资金饱和程度。红色长柱表示资金极度饱和（数值>=1），可能预示短期情绪过热。
黑马跟踪与操盘信号：
黑马跟踪：显示价格上穿特定均线（TT1）后的持续周期数，用于跟踪强势启动的个股。
操盘信号：当“黑马跟踪”周期重新开始计数（即价格最新上穿TT1）时，在副图位置标记“操”字，提示关注或操作时机。
涨幅跟踪：动态显示该“黑马”自启动点以来的累计涨幅。
全仓信号：结合价格位置、均线排列及一个60周期的摆动指标，产生一个“全仓”买入信号，条件较为苛刻，旨在捕捉大级别行情的起点。
指标显示：
指标在副图区域绘制多条曲线和丰富的图文字符。主要包括：V3摆动曲线、RSI1曲线及其压力支撑线、资金饱和度柱状图、以及大量的“买”、“卖”、“抄”、“顶”、“底”、“操”等文字标记和图标，信号直观。
使用要点：
1. 指标信号繁多，需分清主次。核心趋势判断依据V1与V2的关系（上方为强，下方为弱），在此背景下，再结合V3和RSI的短期信号进行操作，可提高胜率。
2. 背离信号（顶背离、底背离）属于预警信号，表明原有趋势动能可能衰竭，但并非立即的反转信号，需结合其他信号或价格形态确认。
3. “黑马跟踪”与“操” 信号用于追踪强势股的第二波或回调后的再次启动点，需结合股价整体位置和量能综合判断。
4. 所有信号均应结合K线形态、成交量以及大盘环境进行综合研判，避免单一信号盲从。
N1:=5;
N2:=10;
N3:=20;
N4:=60;
P:=20;
V1:=EMA(CLOSE,5)-EMA(CLOSE,340);
V2:=EMA(V1,144);
V3:(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,COLOR00BB00;
卖出:-1*IF((CROSS(98.5,V3) AND V1>V2) AND COUNT(V3>97,3)=2,20,0)+90,COLORFF9900;
抄:IF(CROSS(V3,5) AND V1<V2,-20,0)-50,COLOR0090FF;
DRAWTEXT(CROSS(V3,5) AND V1<V2,-45,'抄'),COLORFF00FF;
DRAWTEXT(CROSS(98.5,V3) AND V1>V2,75,'卖'),COLOR00FF00;
TT2:=DMA((((HIGH + LOW) + (CLOSE * 2)) / 4.15),0.9);
TT1:=REF(EMA(TT2,3),1);
LC := REF(CLOSE,1);
RSI1:SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*100;
短卖:=STICKLINE(CROSS(RSI1,80),60,95,2,0),COLORFF9900,LINETHICK1;
DRAWTEXT(CROSS(RSI1,80),98,' 卖'),COLORFFFFCC;
买R:STICKLINE(CROSS(RSI1,50),30,70,1,0),COLORRED,LINETHICK1;
DRAWTEXT(CROSS(RSI1,50),50,' 买'),COLORFFFFCC;
{- }
压力:= HHV(MA(RSI1,3),13),COLORGREEN;
支撑:=LLV(MA(RSI1,3),13),COLORYELLOW;
AA:=REF(RSI1,N2)=HHV(RSI1,2*N2+1);
BB:=BACKSET(AA,N2+1);
CC:=FILTER(BB,N2) AND RSI1=HHV(RSI1,N2+1);
K1:=BARSLAST(REF(CC,1));
顶背离:=REF(CLOSE,K1+1)<CLOSE AND REF(RSI1,K1+1)>RSI1 AND CC;
DRAWTEXT(顶背离,RSI1*1.2,'顶');
DRAWLINE(CC,RSI1,FILTER(顶背离>0,5),RSI1,0),COLORWHITE;
DRAWICON(顶背离,RSI1*1.1,2);
AA2:=REF(RSI1,N2)=LLV(RSI1,2*N2+1);
BB2:=BACKSET(AA2,N2+1);
CC2:=FILTER(BB2,N2) AND RSI1=LLV(RSI1,N2+1);
K2:=BARSLAST(REF(CC2,1));
底背离:REF(CLOSE,K2+1)>CLOSE AND REF(RSI1,K2+1)<RSI1 AND CC2;
DRAWTEXT(底背离,RSI1*1.2,'底');
DRAWLINE(CC2,RSI1,FILTER(底背离>0,5),RSI1,0),COLORWHITE;
DRAWICON(底背离,RSI1*0.98,1);
A:=EMA(AMOUNT/C/1000000,7);
MID :=EMA(A,P);
UPPER:=MID + 196/100*STD(A,25);
LOWER:=MID - 196/100*STD(A,25);
饱和度:IF((A-LOWER)/(UPPER-LOWER)>1,1,(A-LOWER)/(UPPER-LOWER)),COLORWHITE;
{STICKLINE(((CLOSE > 0) AND ISLASTBAR ),0,1,3,1),COLORFFFFFF;
STICKLINE(((CLOSE > 0) AND ISLASTBAR ),0.01,0.99,2.5,1),COLORFFFF00;}
STICKLINE(饱和度>=1,0,90,4,0),COLORRED;
H1:=EMA(C,8);
H2:=EMA(H1,20);
HH2:=EMA(CLOSE,14);
HH3:=MEMA(CLOSE,4);
VAR1:=(CLOSE-LLV(LOW,60.135))/(HHV(HIGH,60.135)-LLV(LOW,60))*80;
VAR2:=SMA(VAR1,7,1);
VAR3:=SMA(VAR2,5,1);
全仓:CROSS(VAR2,VAR3) AND VAR2<20 AND HH2>HH3;
N5:=BARSLAST(CROSS(CLOSE,TT1));
N6:=BARSLAST(CROSS(TT1,CLOSE));
黑马跟踪:IF(N5<N6,N5+1,0);
操:DRAWTEXT(黑马跟踪=1,TT2 + TT2*(0.5),'操'),COLORRED;
涨幅:DYNAINFO(14)*100,LINETHICK0 ;
涨踪:(C-REF(C,黑马跟踪))/REF(C,黑马跟踪)*100;
