KDJ和MACD是我们经常用到的指标，特别是它们在周线下的形态我们会特别关注，因此免不了经常在日周两个周期内切换。本指标免去了这种切换的麻烦，同时又不像有些周线指标日显时需要不断缩小才能窥见全貌。
使用中需要注意的问题我已经在指标内做了说明，不需要可自行编辑删除。
这两个指标来自网络，我只是做了些整理。
{日周MACD同图副图源码如下}
DRAWTEXT_FIX(1,0.01,0.01,0,'1、在日线观察周MACD，与它在周线的样子是一样的'),COLORWHITE;
DRAWTEXT_FIX(1,0.01,0.06,0,'2、在日线分析周MACD时，注意对应的最右边一根K线是最近的这周'),COLORWHITE;
DRAWTEXT_FIX(1,0.01,0.11,0,'3、相应的，往左数第二根K线对应上周，接着是上上周...'),COLORWHITE;
DRAWTEXT_FIX(1,0.01,0.16,0,'4、周线MACD的具体数值看上方，这才是是正确的'),COLORWHITE;
{MACD}
DDATE:DATE,NODRAW,COLORRED;
DIF:EMA(C,12)-EMA(C,26),COLORWHITE;
DEA:EMA(DIF,9),COLORYELLOW;
MACD:(DIF-DEA)*2,NODRAW,COLORMAGENTA;
{显示MACD柱}
STICKLINE(MACD>0,MACD,0,1,1),COLORRED;
STICKLINE(MACD<0,0,MACD,1,1),COLORGREEN;
TESTSKIP(PERIOD!=5);
{周MACD}
D1:=DATE;
DIF1:=MACD.DIF#WEEK;
DEA1:=MACD.DEA#WEEK;
WEK:=REFX(WEEKDAY<REF(WEEKDAY,1) OR
DATETODAY(DATE)-DATETODAY(REF(DATE,1))>=7,1) OR ISLASTBAR;
D2:=IF(WEK,D1,DRAWNULL);
DIF2:=IF(WEK,DIF1,DRAWNULL);
DEA2:=IF(WEK,DEA1,DRAWNULL);
周日期:ALIGNRIGHT(D2),NODRAW,COLORRED;
周DIF:ALIGNRIGHT(DIF2),NODRAW,COLORWHITE;
周DEA:ALIGNRIGHT(DEA2),NODRAW,COLORYELLOW;
周MACD:(周DIF-周DEA)*2,NODRAW,COLORMAGENTA;
A1:=CONST(LLV(MACD,150))*2;
Q:=0.6;
NOTEXTA1:A1,COLOR336699,DOTLINE;
{显示周MACD柱}
STICKLINE(周MACD>0,A1,周MACD*Q+A1,1,1),COLOR0099FF;
STICKLINE(周MACD<0,A1,周MACD*Q+A1,1,1),COLOR999900;
{显示周MACD均线}
NOTEXT周DIF:周DIF*Q+A1,DOTLINE,COLORLIRED;
NOTEXT周DEA:周DEA*Q+A1,DOTLINE,COLORCYAN;
{日周KDJ同图副图源码如下}
DRAWTEXT_FIX(1,0.01,0.01,0,'1、在日线观察周KDJ，与它在周线的样子是一样的'),COLORWHITE;
DRAWTEXT_FIX(1,0.01,0.06,0,'2、在日线分析周KDJ时，注意对应的最右边一根K线是最近的这周'),COLORWHITE;
DRAWTEXT_FIX(1,0.01,0.11,0,'3、相应的，往左数第二根K线对应上周，接着是上上周...'),COLORWHITE;
DRAWTEXT_FIX(1,0.01,0.16,0,'4、周线KDJ的具体数值看上方，这才是是正确的'),COLORWHITE;
{KDJ}
DDATE:DATE,NODRAW,COLORRED;
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:SMA(RSV,3,1),COLORFFFFFF;
D:SMA(K,3,1),COLOR00FFFF;
J:3*K-2*D,COLORFF00FF;
TESTSKIP(PERIOD!=5);
{周KDJ}
D1:=DATE;
K01:=KDJ.K#WEEK;
D01:=KDJ.D#WEEK;
J01:=KDJ.J#WEEK;
WEK:=REFX(WEEKDAY<REF(WEEKDAY,1) OR DATETODAY(DATE)-DATETODAY(REF(DATE,1))>=7,1)
OR ISLASTBAR;
D2:=IF(WEK,D1,DRAWNULL);
K02:=IF(WEK,K01,DRAWNULL);
D02:=IF(WEK,D01,DRAWNULL);
J02:=IF(WEK,J01,DRAWNULL);
周日期:ALIGNRIGHT(D2),NODRAW,COLORRED;
周K:ALIGNRIGHT(K02),NODRAW,COLORFFFFFF;
周D:ALIGNRIGHT(D02),NODRAW,COLOR00FFFF;
周J:ALIGNRIGHT(J02),NODRAW,COLORFF00FF;
A1:=CONST(LLV(J,150))*5;
Q:=0.6;
{NOTEXTA1:A1,COLOR336699,DOTLINE;}
{显示周KDJ}
NOTEXT周K:周K*Q+A1,COLORFFFFFF,DOTLINE;
NOTEXT周D:周D*Q+A1,COLOR00FFFF,DOTLINE;
NOTEXT周J:周J*Q+A1,COLORFF00FF,DOTLINE;
